# Maintainer: lilydjwg <lilydjwg@gmail.com>
# Contributor: Solomon Choina <shlomochoina@gmail.com0
pkgname=wayfire-lily-git
pkgver=0.11.0.20260630.101039.gef322743
pkgrel=2
pkgdesc="3D wayland compositor (lilydjwg's version)"
arch=('x86_64')
url="https://github.com/lilydjwg/wayfire"
license=('MIT')
depends=('wlroots0.20' 'cairo' 'pango' 'glm' 'libjpeg-turbo' 'yyjson' 'libyyjson.so'
         wlroots-lily-git # for vulkan_effects
        )
makedepends=('git' 'meson' 'ninja' 'wayland-protocols' 'doctest' 'vulkan-headers')
optdepends=()
provides=(wayfire wayfire-git)
conflicts=(wayfire wayfire-git)
source=(wayfire::git+$url.git)
sha256sums=(SKIP)

pkgver () {
    cd "$srcdir/wayfire"
    (
        set -o pipefail
        version=$(grep -zoP "project\([^)]*\)" meson.build | xargs --null echo | grep -oP "^\sversion:\s'\K[^']*")
        printf "${version}.%s.g%s" "$(TZ=UTC git log -1 --pretty='%cd' --date=format-local:%Y%m%d.%H%M%S)" "$(git log -1 --format='%h')"
    )
}

build() {
    cd "$srcdir/wayfire"
    arch-meson \
        --buildtype=debug \
        -Dtests=disabled \
        -Duse_system_wfconfig=disabled \
        -Duse_system_wlroots=enabled \
        -Dprint_trace=false \
        -Dvulkan_effects=true \
        . \
        build
    ninja -C build
}

package() {
    cd "$srcdir/wayfire"
    DESTDIR="${pkgdir}/" ninja -C build install
    install -m644 wayfire.ini "${pkgdir}/usr/share"
}
