# Maintainer: erk <v at erk dot io>
pkgname=vnote-git
pkgver=3177.fa2d64e3
epoch=3
pkgrel=1
pkgdesc="A Vim-inspired note-taking application, especially for Markdown."
arch=('x86_64')
url='https://tamlok.github.io/vnote/'
license=('MIT')
depends=(qt6-webengine qt6-svg qt6-webchannel qt6-5compat qtkeychain-qt6 cmark)
makedepends=(git cmake qt6-tools clang lld vulkan-headers)
provides=('vnote')
conflicts=('vnote')
source=("git+https://github.com/vnotex/vnote.git"
        "vtextedit-system-cmark.patch")
sha256sums=('SKIP'
            '346636ee23a174003ab19af2522b8f1d608f7c6ec408351eb0f3ba1348a08aa4')

gitname="vnote"

pkgver() {
    cd "$srcdir/$gitname"
    printf "%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
    cd "$srcdir/$gitname"
    git submodule update --init --recursive
    patch -d libs/vtextedit -Np1 -i "$srcdir/vtextedit-system-cmark.patch"
}
build() {
  export CC=/usr/bin/clang CXX=/usr/bin/clang++
  export LD="/usr/bin/lld"
  export LDFLAGS="-fuse-ld=lld"
  export CXXFLAGS+=" -I/usr/include/qt6keychain"

  cmake -B build -S "vnote" -Wno-dev \
    -DCMAKE_POLICY_VERSION_MINIMUM=3.5 \
    -DUSE_LD_GOLD=OFF \
    -DCMAKE_BUILD_TYPE=None \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DVNOTE_BUILD_TESTS=OFF

  cmake --build build
}
package() {
    cd "$srcdir/build"
    make DESTDIR="$pkgdir" install
}
