# Maintainer: Lukas Weber <laochailan web de>
# Contributor: Andrei Alexeyev <akari taisei-project org>
# Contributor: cyberpunkrocker <l33tmmx gmail com>
# Contributor: carstene1ns <arch carsten-teibes de> - http://git.io/ctPKG

pkgname=taisei-gles
_pkgname=${pkgname%-gles}
pkgver=1.4.6
pkgrel=1
pkgdesc="Open source Touhou clone (using OpenGL ES backends)"
arch=('i686' 'x86_64')
url="https://taisei-project.org/"
license=('MIT')
depends=(
	'opengl-driver'
	'cglm'
	'sdl3'
	'freetype2'
	'glibc'
	'glslang'
	'libgcc'
	'libpng'
	'libstdc++'
	'libunibreak'
	'libwebp'
	'hicolor-icon-theme'
	'openssl'
	'opusfile'
	'spirv-cross'
	'zlib'
	'zstd'
)
makedepends=('meson' 'python-docutils' 'gamemode')
optdepends=('gamemode: GameMode integration')
conflicts=("${_pkgname}")
provides=("${_pkgname}")
source=("https://github.com/taisei-project/taisei/releases/download/v${pkgver}/${_pkgname}-${pkgver}.tar.xz")
sha256sums=('18d03c67dcc8c7faff22e8defdafc3a734b46c591618d1a678e6e914846889d9')

build() {
	cd "${_pkgname}-${pkgver}/"
	arch-meson --auto-features auto build -Dr_gles30=enabled -Dr_default=gles30
	ninja -C build
}

package() {
	cd "${_pkgname}-${pkgver}/"
	DESTDIR="${pkgdir}" ninja install -C build
	install -Dm644 COPYING{,_CN}.txt -t "${pkgdir}/usr/share/licenses/${pkgname}/"
}
