# Maintainer: Lukas Weber <laochailan web de>
# Contributor: Andrei Alexeyev <akari taisei-project org>
# Contributor: cyberpunkrocker <l33tmmx gmail com>
# Contributor: carstene1ns <arch carsten-teibes de> - http://git.io/ctPKG

pkgname=taisei-git
_pkgname=${pkgname%-git}
pkgver=1.4.r760.g4e21fc3
pkgrel=1
pkgdesc="Open source Touhou clone"
arch=('i686' 'x86_64')
url="https://taisei-project.org/"
license=('MIT')
depends=(
	'opengl-driver'
	'cglm'
	'sdl3'
	'freetype2'
	'glibc'
	'libgcc'
	'libpng'
	'libstdc++'
	'libunibreak'
	'libwebp'
	'hicolor-icon-theme'
	'openssl'
	'opusfile'
	'zlib'
	'zstd'
)
makedepends=('git' 'meson' 'python-docutils' 'gamemode')
optdepends=('gamemode: GameMode integration')
conflicts=("${_pkgname}")
provides=("${_pkgname}")
source=(
	"git+https://github.com/taisei-project/${_pkgname}.git"
	"git+https://github.com/taisei-project/SDL_GameControllerDB.git"
	"git+https://github.com/taisei-project/koishi.git"
	"git+https://github.com/taisei-project/basis_universal.git"
)
sha256sums=('SKIP' 'SKIP' 'SKIP' 'SKIP')

pkgver() {
	cd "${_pkgname}/"
	git describe --long --tags --abbrev=7 | sed 's/\([^-]*-g\)/r\1/;s/-/./g;s/v//'
}

prepare() {
	cd "${_pkgname}/"
	git submodule init
	git config submodule.external/gamecontrollerdb.url "${srcdir}/SDL_GameControllerDB"
	git config submodule.external/koishi.url "${srcdir}/koishi"
	git config submodule.external/basis_universal.url "${srcdir}/basis_universal"
	git -c protocol.file.allow=always submodule update
}

build() {
	cd "${_pkgname}/"
	arch-meson --auto-features auto build
	ninja -C build
}

package() {
	cd "${_pkgname}/"
	DESTDIR="${pkgdir}" ninja install -C build
	install -Dm644 COPYING{,_CN}.txt -t "${pkgdir}/usr/share/licenses/${pkgname}/"
}
