# Maintainer: let <let@notlet.dev>

pkgname=stabilitymatrix
pkgver=2.16.2
pkgrel=1
pkgdesc='Multi-Platform Package Manager for Stable Diffusion'
arch=('any')
url='https://github.com/LykosAI/StabilityMatrix'
license=('AGPL3')

depends=('dotnet-runtime-9.0' 'libxcrypt-compat')
makedepends=(
    'dotnet-sdk-9.0'
    'git'
)

options=('!strip')

source=(
    'zone.lykos.stabilitymatrix.png'
    'zone.lykos.stabilitymatrix.desktop'
    "git+https://github.com/LykosAI/StabilityMatrix#tag=v${pkgver}"
)
sha256sums=('0c32dcd560dfadae6c8cc1486fba1227e9cf93a55e3ba262571e83052e1bf22e'
            '6907f3fc4dbf9140af924977c18460b24d220dab6c7871cdd3e8f4cd5a1e1635'
            '42de681b6b17161e7d1b534a6bccdac7bc6d2c528c9ec9afa95b2591d9065704')

build() {
    cd "$srcdir/StabilityMatrix"
    dotnet publish "./StabilityMatrix.Avalonia/StabilityMatrix.Avalonia.csproj" -o out -c Release -r linux-x64 -p:Version=$pkgver
}

package() {
    mkdir -p "$pkgdir/opt"
    mv "$srcdir/StabilityMatrix/out" "${pkgdir}/opt/$pkgname"

    # Make a Data directory so that choosing portable mode doesn't error.
    mkdir -m777 "$pkgdir/opt/$pkgname/Data"

    # Desktop file and icon
    install -Dm644 "zone.lykos.stabilitymatrix.desktop" "${pkgdir}/usr/share/applications/zone.lykos.stabilitymatrix.desktop"
    install -D "zone.lykos.stabilitymatrix.png" "${pkgdir}/usr/share/icons/hicolor/512x512/apps/zone.lykos.stabilitymatrix.png"

}
