# Maintainer: Hao Long <imlonghao@archlinuxcn.org>
# Contributor: Andrea Mazzoleni <amadvance@gmail.com>

pkgname=snapraid-daemon
pkgver=1.14
pkgrel=1
pkgdesc="A background service with a built-in Web UI that automates SnapRAID operations"
arch=('x86_64')
url="https://www.snapraid.it/"
license=('GPL-3.0-or-later')
depends=('glibc' 'zlib' 'zstd' 'snapraid>=14.1')
makedepends=('zip')
backup=('etc/snapraidd.conf')
source=("https://github.com/amadvance/$pkgname/releases/download/v$pkgver/$pkgname-$pkgver.tar.gz")
b2sums=('a22ca8d5a83568ba3acd45017c8b6545aee45f78d44ffd0d4b43cc4a62eaa4b3e448f82f174337e36203d97992f5f18ff3b85795d376fc8be180919ac7107dee')

build() {
  cd "$pkgname-$pkgver"
  ./configure --prefix=/usr --sysconfdir=/etc
  make
}

package() {
  cd "$pkgname-$pkgver"
  make DESTDIR="$pkgdir/" install
  install -Dm644 snapraidd.yaml "$pkgdir/usr/share/doc/$pkgname/snapraidd.yaml"
  install -Dm644 AUTHORS "$pkgdir/usr/share/doc/$pkgname/AUTHORS"
  install -Dm644 HISTORY "$pkgdir/usr/share/doc/$pkgname/HISTORY"
  install -Dm644 README "$pkgdir/usr/share/doc/$pkgname/README"
  install -Dm644 commander.zip "$pkgdir/usr/share/snapraidd/commander.zip"
  install -Dm644 snapraidd.conf.example "$pkgdir/etc/snapraidd.conf"
}
