# Maintainer: Hu Butui <hot123tea123@gmail.com>
# Contributor: Carlos Aznarán <caznaranl@uni.pe>
# Contributor: Jingbei Li <i@jingbei.li>
# Contributor: Francois Boulogne <fboulogne at april dot org>
_pkgname=pywt
pkgname=python-pywavelets
pkgver=1.9.0
pkgrel=3
pkgdesc="Wavelet transform module"
arch=(x86_64)
url="https://github.com/PyWavelets/pywt"
license=(MIT)
depends=(
  python-numpy
)
makedepends=(
  cython
  meson-python
  python-build
  python-installer
  python-wheel
)
optdepends=(
  'python-matplotlib: for plotting support'
  'python-scipy: for scipy.signal.cwt (FFT-based continuous wavelet transforms)'
)
source=(${pkgname}-${pkgver}.tar.gz::https://github.com/PyWavelets/pywt/archive/refs/tags/v${pkgver}.tar.gz)
sha512sums=('141b60ee092a08ce174c6f796fdf8434b7b106110f9d59f5593161fcc5c95b2df4394a604f418bdd414907e5a4470ea7ce5f60ef4ce72033251bb00a14c710de')

build() {
  cd ${_pkgname}-${pkgver}
  python -m build --wheel --skip-dependency-check --no-isolation
}

package() {
  cd ${_pkgname}-${pkgver}
  python -m installer --destdir="${pkgdir}" dist/*.whl
  install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
}
# vim:set ts=2 sw=2 et:
