# Maintainer: Butui Hu <hot123tea123@gmail.com>

_pkgname=hydra
pkgname=python-hydra-core
pkgver=1.3.5
pkgrel=1
pkgdesc='A framework for elegantly configuring complex applications'
arch=('any')
url='https://hydra.cc'
license=('MIT')
depends=(
  python-omegaconf
  python-packaging
)
makedepends=(
  antlr4
  python-build
  python-installer
  python-setuptools
  python-wheel
)
source=("${_pkgname}-${pkgver}.tar.gz::https://github.com/facebookresearch/hydra/archive/refs/tags/v${pkgver}.tar.gz")
sha512sums=('09abdd916d70fba8d51a85b60c84723f58979a74d0cc42249bd4e1be79c0a0f55c7df1fe9e9e9100308a955bbdf96052de0c3f7a1fae057a5d7a434cddd479f9')

prepare() {
  # use system antlr4
  sed -i 's#join(root_dir, "bin/antlr-4.9.3-complete.jar")#"/usr/share/java/antlr-complete.jar"#' "${_pkgname}-${pkgver}/build_helpers/build_helpers.py"
}
build() {
  cd "${_pkgname}-${pkgver}"
  python -m build --wheel --no-isolation
}

package() {
  cd "${_pkgname}-${pkgver}"
  python -m installer --destdir="$pkgdir" dist/*.whl
  install -Dm644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
}
# vim:set ts=2 sw=2 et:
