# Maintainer: Xeonacid <h.dwwwwww@gmail.com>

_name=eth-typing
pkgname=python-${_name}
pkgver=6.0.0
pkgrel=1
pkgdesc="Common type annotations for ethereum python packages"
arch=(any)
url="https://github.com/ethereum/${_name}"
license=(MIT)
depends=(python python-typing_extensions)
makedepends=(python-build python-installer python-setuptools python-wheel python-sphinx python-sphinx_rtd_theme)
checkdepends=(python-pytest)
source=(${_name}-${pkgver}.tar.gz::${url}/archive/v${pkgver}.tar.gz)
sha512sums=('25c3f362d02a6086e7d1805328ac7c4605d6abf15c4dd2fdc098ee55783115908c00a9eabfab9546ecdf147ec507a34bc2d2f6274fb2e2c67623245aa18ab308')

build() {
  cd $_name-$pkgver
  python -m build --wheel --no-isolation
  make -C docs man
}

check(){
  cd $_name-$pkgver
  python -m venv --system-site-packages test-env
  test-env/bin/python -m installer dist/*.whl
  test-env/bin/python -m pytest -vv --showlocals tests/
}

package() {
  cd $_name-$pkgver
  python -m installer --destdir="$pkgdir" dist/*.whl
  install -Dm644 docs/_build/man/eth_typing.1 -t "$pkgdir/usr/share/man/man1"
  install -Dm 644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
}
