# Maintainer: Hu Butui <hot123tea123@gmail.com>
# Contributor: Miguel Revilla <yo@miguelrevilla.com>
# Contributor: joyfulgirl <joyfulgirl (at) archlinux.us>

pkgname=pspp
pkgver=2.1.1
pkgrel=1
pkgdesc='Statistical analysis program. Free replacement for SPSS'
arch=('x86_64')
url='http://www.gnu.org/software/pspp'
license=('GPL-3.0-or-later')
depends=(
  cairo
  glib2
  gsl
  gtk3
  gtksourceview4
  libxml2
  pango
  postgresql-libs
  readline
  spread-sheet-widget
  zlib
  gettext
)
makedepends=(
  glib2-devel
  python
)
options=('!libtool' '!emptydirs')
source=("${pkgname}-${pkgver}.tar.gz::https://ftp.gnu.org/gnu/pspp/${pkgname}-${pkgver}.tar.gz"
        "${pkgname}-${pkgver}.tar.gz.sig::https://ftp.gnu.org/gnu/pspp/${pkgname}-${pkgver}.tar.gz.sig"
)
sha256sums=('b5e550937bdfa66a1e6ca729195272e8e5e66b3e04686b2d83fb2e66d4ef14c3'
            'SKIP')
validpgpkeys=('C2D1AB061656AAC54B5E975485199DE8C6648E90')

prepare() {
  cd "${pkgname}-${pkgver}"
  sed -i 's/.*_GL_EXTERN_C.*bsearch.*/#undef bsearch\n&/' gl/stdlib.in.h
  sed -i 's/.*_GL_EXTERN_C.*wmemchr.*/#undef wmemchr\n&/' gl/wchar.in.h
}

build() {
  cd "${pkgname}-${pkgver}"
  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc
  make
}

package() {
  cd "${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
}
# vim:set ts=2 sw=2 et:
