# Maintainer: Coelacanthus <coelacanthus@archlinuxcn.org>    
# Contributor: Jaja <jaja@mailbox.org>
# Contributor: floriplum <floriplum@mailbox.org>
# Contributor: various people submitting to 'chaotic-aur' repo
# Contributor: barfin (aka RogueGirl) <barfin@protonmail.com>

pkgname=proton-ge-custom-bin
pkgdesc='A fancy custom distribution of Valves Proton with various patches'
url='https://github.com/GloriousEggroll/proton-ge-custom'
pkgver=11.3
pkgrel=1
arch=('x86_64')
_tag="GE-Proton${pkgver//./-}"
_pkgname="${pkgname//-bin/}"
license=('BSD-3-Clause AND LGPL-2.1-or-later AND Zlib AND MIT AND MPL-2.0 AND OFL-3.0 AND LicenseRef-STEAMWORKS-SDK-license')
changelog=changelog.md
provides=(
  'proton'
  "proton-ge-custom=${pkgver}"
)
conflicts=(
  'proton-ge-custom'
)
makedepends=(
  'python-vdf'
)
depends=(
  'python'
)
optdepends=(
  'kdialog: KDE splash dialog support'
  'zenity: GNOME splash dialog support'
  'python-kivy: splash dialog support (big picture mode)'
  'steam: use proton with steam like intended'
  'vulkan-icd-loader: dxvk dependency'
  'lib32-vulkan-icd-loader: dxvk dependency for 32bit prefixes'
  'vulkan-driver: driver to be used by dxvk'
  'winetricks: protonfixes backend'
  'xboxdrv: gamepad driver service'
)
options=(emptydirs !strip)

source=(
  "${pkgname}_${_tag}.tar.gz::${url}/releases/download/${_tag}/${_tag}.tar.gz"
  'deversionized.py'
)
b2sums=('9f18ec34dc5bf1114b01e3b28239dacf84a73e7409018fc5f0dec6612e1ca6108287c2d31afe4e3c372874422b127bc9a9b4c49a651485f6f382c1d549d0eb40'
        'a07fd87e91df85ca5441396b1e94c94474526bf932389aca9edc60fcd0e8343dc42159577172d66f37e39f6b5fa6efe0929165742f6c4fafb49c3da8112884c1')

build() {
  pushd "${_tag}"
    python "${srcdir}/deversionized.py"
    sed -E -i 's/^\s+"[A-Z_]+": ".*",\s*$/#&/g' user_settings.sample.py
  popd
}

package() {
  _protondir="usr/share/steam/compatibilitytools.d/${_pkgname}"
  install -d "${pkgdir}/${_protondir}/"
  pushd "${_tag}"
    install -v -Dm644 -t "${pkgdir}/usr/share/licenses/${pkgname}" \
      LICENSE \
      LICENSE.OFL \
      PATENTS.AV1
    install -v -Dm644 user_settings.sample.py "${pkgdir}/etc/proton/Proton-GE/user_settings.py"
    cp -v -rf --no-dereference --reflink=auto --preserve=mode,links * "${pkgdir}/${_protondir}"
    ln -v -s -r "${pkgdir}/etc/proton/Proton-GE/user_settings.py" "${pkgdir}/${_protondir}/user_settings.py"
  popd
}
