# Maintainer: Rocket Aaron
# Contributor: huyz


pkgname=plasma-login-manager-git
_pkgname=plasma-login-manager
pkgver=6.6.90.r31.g52aefca
pkgrel=1
pkgdesc='Plasma Login Manager (git version)'
url='https://invent.kde.org/plasma/plasma-login-manager'
arch=(x86_64)
license=(GPL-2.0-or-later)
depends=(glibc
         kauth
         kcmutils
         kconfig
         kcoreaddons
         kdbusaddons
         ki18n
         kio
         kirigami
         kpackage
         kservice
         kwindowsystem
         layer-shell-qt
         libkscreen
         libplasma
         libstdc++
         libxau
         pam
         plasma-workspace
         qt6-5compat
         qt6-base
         qt6-declarative
         sh
         systemd-libs)
makedepends=(extra-cmake-modules
             ninja
             git
             qt6-tools)
source=('git+https://invent.kde.org/plasma/plasma-login-manager.git/')
sha256sums=('SKIP')
provides=(${_pkgname})
conflicts=(${_pkgname})

pkgver() {
    cd $_pkgname
    git describe --long --abbrev=7 | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
    cd $_pkgname
    # allow build for older version of plasma
    sed -i 's/set(PROJECT_DEP_VERSION "[0-9.]*")/set(PROJECT_DEP_VERSION "6.0.0")/' CMakeLists.txt
}

build() {
    cmake -B build -S $_pkgname -GNinja \
      -DCMAKE_INSTALL_LIBEXECDIR=lib \
      -DDBUS_CONFIG_FILENAME=plasma_org.freedesktop.DisplayManager.conf
    cmake --build build
}

package() {
    DESTDIR="$pkgdir" cmake --install build
}
