# Maintainer  : Integral         <integral (@) member.fsf.org>
# Contributor : Thaodan          <AUR+me@thaodan.de>
# Contributor : Firef0x          <Firefgx {at) gmail [dot} com>
# Contributor : Bernhard Walle   <bwalle.de: bernhard            >
# Contributor : Jesse Jaara      <gmail.com, mail.ru: jesse.jaara>
# Contributor : Armin Wehrfritz
# Contributor : Patrick McCarty  <pnorcks at gmail dot com>

pkgname=osc
pkgver=1.27.3
pkgrel=1
pkgdesc="Command line client for the openSUSE Build Service"
arch=('any')
url="https://github.com/openSUSE/${pkgname}"
license=('GPL-2.0-or-later')
depends=('python' 'python-cryptography' 'python-ruamel-yaml' 'python-urllib3' 'python-zstandard' 'diffstat')
makedepends=('python-setuptools')
optdepends=('obs-build: required to run local builds'
	'obs-service-format_spec_file: for running the format_spec_file source service'
	'obs-service-download_files: for running the download_files source service'
	'python-keyring: keyring support'
	'python-progressbar: progressbar support for operations like uploading and services'
	'python-distro: Linux OS platform information API'
)
source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/${pkgver}.tar.gz")
sha256sums=('72e90ff3d278fc072f640223cf911635eed58c7ecbac4da722205a0ebf83ddf0')

build() {
	cd "${pkgname}-${pkgver}/"
	python setup.py build
}

package() {
	cd "${pkgname}-${pkgver}/"
	python setup.py install --root="${pkgdir}/" --optimize=1 --prefix=/usr

	install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}/"
	install -d "${pkgdir}/usr/share/doc/${pkgname}"
	cp -r doc/* "${pkgdir}/usr/share/doc/${pkgname}/"

	cd contrib
	install -Dm644 "complete.sh" "${pkgdir}/usr/share/bash-completion/completions/${pkgname}"
	install -Dm644 "${pkgname}.zsh" "${pkgdir}/usr/share/zsh/site-functions/_${pkgname}"
	install -Dm644 "${pkgname}.fish" -t "${pkgdir}/usr/share/fish/vendor_completions.d/"
}
