# Maintainer: lsf

pkgname=opensnitch-ebpf-module-git
_pkgname=opensnitch
pkgver=1.8.0.r224.a1353848
pkgrel=1
pkgdesc="eBPF process monitor module for opensnitch"
arch=('i686' 'x86_64' 'armv6h' 'armv7h' 'aarch64')
url="https://github.com/evilsocket/${_pkgname}"
license=('GPL-3.0-or-later')
makedepends=('git' 'clang' 'llvm' 'libelf'
	'bc' 'rsync' 'linux-headers' 'coreutils')
depends=("${_pkgname}")
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=("git+https://github.com/evilsocket/${_pkgname}.git")
sha256sums=('SKIP')
options=('!strip') # we're stripping with llvm-strip

pkgver() {
	cd "${_pkgname}/"
	git describe --long | sed 's/^v//;s/-rc./rc/;s/\([^-]*-\)g/r\1/;s/-/./g'
}

build() {
	cd "${_pkgname}/ebpf_prog/"
	KERNEL_VER=$(pacman -Si linux-headers | grep Version | awk '{print $3}' | sed 's/.arch/-arch/')
	KERNEL_DIR="/usr/lib/modules/${KERNEL_VER}/build" KERNEL_HEADERS="${KERNEL_DIR}" ARCH="${arch}" make all
}

package() {
	install -Dm644 ${_pkgname}/ebpf_prog/${_pkgname}{,-{procs,dns}}.o -t "${pkgdir}/usr/lib/opensnitchd/ebpf/"
}
