# Maintainer: Gustavo Alvarez Lopez <sl1pkn07@gmail.com>

pkgname=np2kai-git
pkgver=1158.e2dc9046
pkgrel=1
pkgdesc="Neko Project II Kai, a PC-9801 emulator. (GIT version)"
arch=('x86_64')
url='http://domisan.sakura.ne.jp/article/np2kai/np2kai.html'
license=('MIT')
depends=(
  'glibc'
  'libgcc' 'libgcc_s.so'
  'libstdc++' 'libstdc++.so'
  'libcdio'
  'libpng'
  'sdl3'
  'sdl3_ttf'
  'wxwidgets-gtk3'
)
makedepends=(
  'git'
  'cmake'
  'nasm'
  'ninja'
)
conflicts=('np2kai')
provides=('np2kai')
source=(
  'git+https://github.com/AZO234/NP2kai.git'
  '0001-cmake-use-selected-sdl-version-for-wx.patch'
  '0002-fix-video-filter-default-initializer.patch'
  '0003-use-arch-sdl2-ttf-include-path.patch'
)
sha256sums=(
  'SKIP'
  '3ccae90ffeaec978f35948b129ab9ee92b0f168443b103f14a74a151c1528307'
  '7c00588800c51a1ada7d272e46c1c93637bdc52995aabc47241e8e4f3a818254'
  '5de1c118aa121fd424679ad0904e90c50e16fd971df04fd63da06af37c3127fa'
)

pkgver() {
  cd NP2kai
  printf "%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
  cd NP2kai

  patch -Np1 -i ../0001-cmake-use-selected-sdl-version-for-wx.patch
  patch -Np1 -i ../0002-fix-video-filter-default-initializer.patch
  patch -Np1 -i ../0003-use-arch-sdl2-ttf-include-path.patch
}

build() {
  pushd NP2kai
  export NP2KAI_VERSION="$(git describe --tags --abbrev=0)"
  export NP2KAI_HASH="$(git rev-parse --short HEAD)"
  popd

  cmake -S NP2kai -B build \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_MANDIR=/usr/share/man/man1 \
    -DBUILD_WX=ON \
    -DBUILD_X=OFF \
    -DBUILD_SDL=ON \
    -DBUILD_I286=ON \
    -DBUILD_HAXM=ON \
    -DUSE_SDL=3 \
    -DUSE_HAXM=OFF \
    -DUSE_ASYNCCPU=ON \
    -DUSE_VST3SDK=OFF \
    -DCMAKE_C_FLAGS="-Wno-implicit-function-declaration -Wno-incompatible-pointer-types -Wno-int-conversion" \
    -DCMAKE_CXX_FLAGS="-fno-sized-deallocation" \
    -G Ninja

  cmake --build build
}

package() {
  DESTDIR="${pkgdir}" cmake --install build

  install -Dm644 NP2kai/LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
