# Maintainer: Guillaume Dolle  <dev at gdolle.com>
pkgname=micromamba
pkgver=2.9.0
pkgrel=1
pkgdesc="C++ tiny version of mamba, the fast conda package installer"
arch=('aarch64' 'armv7h' 'i686' 'x86_64')
url="https://github.com/mamba-org/mamba"
license=('MIT')
depends=('libarchive.so' 'libcurl.so' 'libsolv' 'fmt' 'simdjson'
         'libspdlog.so' 'libyaml-cpp.so' 'libreproc.so' 'libreproc++.so'
         'libmsgpack-c.so')
makedepends=('gtest' 'termcolor' 'cmake' 'cli11' 'nlohmann-json'
             'ghc-filesystem' 'tl-expected' 'python')
source=(micromamba-${pkgver}.tar.gz::https://github.com/mamba-org/mamba/archive/refs/tags/${pkgver}.tar.gz)
sha256sums=('57befdcc985b07f95d1a495569ac249a270c71167d111374ff08443154821e1d')
conflicts=('micromamba-bin')

build() {
  cd mamba-${pkgver}

  cmake -DCMAKE_BUILD_TYPE=Release \
        -DCMAKE_INSTALL_PREFIX=/usr \
        -DCMAKE_POSITION_INDEPENDENT_CODE=ON \
        -DBUILD_LIBMAMBA=ON \
        -DBUILD_LIBMAMBA_SPDLOG=ON \
        -DBUILD_LIBMAMBAPY=OFF \
        -DBUILD_LIBMAMBA_TESTS=OFF \
        -DBUILD_MAMBA_PACKAGE=OFF \
        -DBUILD_MAMBA=ON \
        -DBUILD_SHARED=ON \
        -DBUILD_STATIC=OFF \
        -DMAMBA_WARNING_AS_ERROR=OFF \
        -B build
  cmake --build build
}

# check() {
#   cd mamba-${pkgver}/build
#   ctest
# }

package() {
  depends+=('libfmt.so')
  cd mamba-${pkgver}
  DESTDIR="${pkgdir}" cmake --install build

  mv "${pkgdir}"/usr/bin/{mamba,micromamba}
}
