# Maintainer: Rocket Aaron <i at rocka dot me>
# Contributor: Nico <d3sox at protonmail dot com>

pkgname=kwin-effects-better-blur-dx
pkgver=2.5.1
pkgrel=4
pkgdesc="Fork of the Plasma 6 blur effect with additional features (including force blur) and bug fixes."
arch=(x86_64)
url="https://github.com/xarblu/kwin-effects-better-blur-dx"
license=(GPL-3.0-or-later)
depends=(glibc
         libstdc++
         libepoxy
         libxcb
         qt6-base
         kcoreaddons
         kconfig
         ki18n
         kwidgetsaddons
         kdecoration
         kcmutils
         kwin)
makedepends=(extra-cmake-modules
             vulkan-headers)
replaces=(kwin-effects-forceblur)
source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/refs/tags/v${pkgver}.tar.gz"
        "${pkgname}.install")
install="${pkgname}.install"
sha256sums=('42152f040434f0adfef55eab510000a5fc00b0afe1935e0dc6f01c766b4c9dbb'
            '3c76155e0bb3fdd7f4ed84b70165063d96a7535ccef86b4e8ae642e42dc4f865')

build() {
    cmake -S "${pkgname}-${pkgver}" -B build \
        -DCMAKE_INSTALL_PREFIX=/usr
    cmake --build build
}

package() {
    DESTDIR="${pkgdir}" cmake --install build
}
