# Maintainer: taotieren <admin@taotieren.com>

pkgname=kicad-hq
_name=${pkgname%-hq}
pkgver=10.0.5
pkgrel=1
pkgdesc="Electronic schematic and printed circuit board (PCB) design tools"
arch=('x86_64')
url="https://gitlab.com/${pkgname}/${_name}"
license=('GPL-3.0-or-later')
depends=(
	abseil-cpp
	boost-libs
	cairo
	curl
	freetype2
	fontconfig
	gcc-libs
	glib2
	glibc
	glu
	gtk3
	libglvnd
	libgit2
	libsecret
	libspnav
	harfbuzz
	hicolor-icon-theme
	nng
	opencascade
	openssl
	poppler-glib
	protobuf
	python
	python-wxpython
	wayland
	webkit2gtk-4.1
	wxwidgets-gtk3
	wxwidgets-common
	unixodbc
	zlib
	zstd
)
makedepends=(
	cmake
	doxygen
	glew
	glm
	ngspice
	mesa
	boost
	swig
	ninja
)
conflicts=("${_name}")
provides=("${_name}")
optdepends=(
	'kicad-library: KiCad symbol, footprint and template libraries'
	'kicad-library-3d: KiCad 3D model libraries'
)
source=("${url}/-/archive/${pkgver}/${_name}-${pkgver}.tar.gz")
sha256sums=('3cc34c981e13a07220084e4b171134c51d49f28447a284d712b98328f44be38a')

build() {
	cmake -B build \
	      -S "${_name}-${pkgver}" \
	      -G Ninja \
	      -D CMAKE_BUILD_TYPE=Release \
	      -D CMAKE_INSTALL_PREFIX=/usr \
	      -D KICAD_USE_EGL=ON \
	      -D KICAD_USE_BUNDLED_GLEW=OFF \
	      -D KICAD_BUILD_I18N=ON \
	      -D KICAD_I18N_UNIX_STRICT_PATH=ON \
	      -D KICAD_BUILD_QA_TESTS=OFF \
	      -D KICAD_UPDATE_CHECK=OFF \
	      -W no-dev

	cmake --build build
}

package() {
	DESTDIR="${pkgdir}" cmake --install build
}
