#Maintainer:    mumi jim <echo "=02bj5yav9Gb0V3bA1Waq9VatVXb" | rev | base64 -d>
# Contributor: Klaus Alexander Seiﬆrup <$(echo 0x1fd+d59decfa=40 | tr 0-9+a-f=x ka-i@p-u.l)>

#Thanks Klaus Alexander Seistrup :)
#this PKGBUILD of Keypunch
#github Repo: https://github.com/bragefuglseth/keypunch/

pkgname="keypunch-git"
_appname="keypunch"
pkgver=7.0.r5.g06a5787
pkgrel=1
epoch=1
pkgdesc='Practice your typing skills'
url='https://github.com/bragefuglseth/keypunch'
arch=('aarch64' 'x86_64')
license=('GPL-3.0-or-later')
provides=('keypunch')
conflicts=('keypunch')
depends=('hicolor-icon-theme' 'graphene' 'gtk4' 'libadwaita')
makedepends=('blueprint-compiler' 'cargo' 'git' 'meson' 'ninja')
source=("git+${url}.git")
sha512sums=('SKIP')

pkgver() {
    cd "${_appname}/"
    git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
    cd "${_appname}/"
    export RUSTUP_TOOLCHAIN=stable
    arch-meson . build
    meson compile -C build
}

package() {
    cd "${_appname}/"
    meson install -C build --destdir "$pkgdir"
}
