# Maintainer: Megumi_fox  <megumifox@archlinuxcn.org>
# Contributor: Jianqiu Zhang <void001@archlinuxcn.org>

_gitname=kcm-colorful
pkgname=kcm-colorful-git
pkgver=1.0.5.r0.g411e8c9
pkgrel=1
pkgdesc='Make your KDE plasma colorful'
arch=('x86_64')
url="https://github.com/IsoaSFlus/kcm-colorful"
license=('GPL2')
depends=('gettext' 'kconfigwidgets' 'systemsettings' 'kcolorchooser')
makedepends=('cmake' 'git' 'extra-cmake-modules' 'qt5-base' 'frameworkintegration' 'kcmutils')

source=(
    "kcm-colorful::git+https://github.com/IsoaSFlus/kcm-colorful"
)

sha256sums=('SKIP')

pkgver() {
	cd $_gitname
#	printf "0.9.6.r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
	git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
    cd $srcdir/kcm-colorful
    git submodule init
    git submodule update
}

build() {
    cd $srcdir/kcm-colorful
    mkdir -p build
    cd build
    cmake -DCMAKE_INSTALL_PREFIX="/usr" -DCMAKE_INSTALL_LIBDIR=lib ..
    make
}

package() {
    cd $srcdir/kcm-colorful/build
    make DESTDIR="$pkgdir" install
}
