# Maintainer: Dee.H.Y <dongfengweixiao at hotmail dot com>

_pkgname="ImageGlass"
pkgname="imageglass"
pkgver=10.0.3.720_rc
pkgrel=2
pkgdesc="lightweight, versatile image viewer"
url="https://imageglass.org"
license=('LicenseRef-imageglass')
arch=('x86_64')

depends=(
  'fontconfig'
  'glibc'
  'hicolor-icon-theme'
  'libgomp'
)
makedepends=(
  'dotnet-sdk'
  'git'
)

_pkgsrc="$pkgname-$pkgver"
_pkgext="tar.gz"
source=(
  "$_pkgsrc.$_pkgext"::"https://github.com/d2phap/ImageGlass/archive/refs/tags/${pkgver//_/-}.$_pkgext"
  'imageglass.desktop'
  'igconfig.default.json'
)
sha256sums=('8e8afde82438e37853252ac5229c4c1905c7d73d161b28db815b8ab0c091725a'
            'b31814a355395b002b8bd2dedc9107f5c288a56998df6e9894379900b6a7c560'
            '21fbac2e5dceccc8b5f1515a7c6621e3bf7ea06479c73f665f7474ad7479e816')
build() {
  cd "$srcdir/${_pkgname}-${pkgver//_/-}/source/"
  dotnet publish ImageGlass.Linux/ImageGlass.Linux.csproj \
    -c Release \
    -r linux-x64 \
    -p:Platform=x64 \
    -p:PublishAot=true \
    -p:PublishSingleFile=true \
    -p:PublishTrimmed=true \
    -o ./artifacts/publish/linux-x64 \
    --self-contained true
}

package() {
  cd "$srcdir/${_pkgname}-${pkgver//_/-}/source/artifacts/publish/linux-x64"
  for file in *; do
    if [[ -f "$file" && "$file" == *.so ]]; then
      install -Dm755 "$file" "$pkgdir/usr/lib/$pkgname/$file"
    fi
  done
  install -Dm755 ImageGlass "$pkgdir/usr/lib/$pkgname/ImageGlass"
  install -dm755 "$pkgdir/usr/bin"
  ln -s "/usr/lib/$pkgname/ImageGlass" "$pkgdir/usr/bin/$pkgname"
  # copy resources
  cp -r "$srcdir/${_pkgname}-${pkgver//_/-}/source/__assets/__app/"* "$pkgdir/usr/lib/$pkgname/"
  # install desktop file and icon
  install -Dm644 "$srcdir/$pkgname.desktop" "$pkgdir/usr/share/applications/$pkgname.desktop"
  install -Dm644 "$srcdir/${_pkgname}-${pkgver//_/-}/source/__assets/logo_c.svg" "$pkgdir/usr/share/icons/hicolor/scalable/apps/$pkgname.svg"
  install -Dm644 "$srcdir/${_pkgname}-${pkgver//_/-}/source/__assets/logo_c_512.png" "$pkgdir/usr/share/icons/hicolor/512x512/apps/$pkgname/$pkgname.png"
  # install default config file
  install -Dm644 "$srcdir/igconfig.default.json" "$pkgdir/usr/lib/$pkgname/igconfig.default.json"
  # install license
  install -Dm644 "$srcdir/${_pkgname}-${pkgver//_/-}/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
