# Maintainer: Rocket Aaron <i at rocka dot me>
# Contributor: Piroro-hs

_pkgname=gsettings-desktop-schemas
pkgname="${_pkgname}-nofont"
pkgver=50.1
pkgrel=1
pkgdesc='Shared GSettings schemas for the desktop (without font dependencies)'
arch=('any')
url="https://gitlab.gnome.org/GNOME/${_pkgname}"
license=('LGPL-2.1-or-later')
depends=('dconf' 'glib2')
makedepends=('glib2-devel' 'gobject-introspection' 'meson')
provides=('gsettings-desktop-schemas' 'gsettings-system-schemas')
conflicts=('gsettings-desktop-schemas' 'gsettings-system-schemas')
source=("${url}/-/archive/${pkgver}/${_pkgname}-${pkgver}.tar.gz"
        '0001-Revert-default-font.patch')
sha256sums=('ac9328c00ca18e5ac921bb2c13048b1ce5b43302b0c8d89d7fec22b05e22ec7a'
            '082cab879b42335261e8b9a81cf62d1df896e89caf86a76446226ce7721a0f25')

prepare() {
  cd "${_pkgname}-${pkgver}"
  patch -p1 -i "${srcdir}/0001-Revert-default-font.patch"
}

build() {
  arch-meson "${_pkgname}-${pkgver}" build
  meson compile -C build
}

check() {
  meson test -C build --print-errorlogs
}

package() {
  meson install -C build --destdir "${pkgdir}"
}
