# Maintainer: Mahdi Sarikhani <mahdisarikhani@outlook.com>
# Contributor: Igor Dyatlov <dyatlov.igor@protonmail.com>

pkgname=gapless
_name=g4music
pkgver=4.6.2
pkgrel=3
pkgdesc="Play your music elegantly (AKA: G4Music)"
arch=('aarch64' 'x86_64')
url="https://gitlab.gnome.org/neithern/g4music"
license=('GPL-3.0-only')
depends=('dconf'
         'gdk-pixbuf2'
         'glib2'
         'glibc'
         'graphene'
         'gst-plugins-base-libs'
         'gstreamer'
         'gtk4'
         'hicolor-icon-theme'
         'libadwaita'
         'pango')
makedepends=('meson' 'vala' git)
optdepends=('gst-plugins-bad: "bad" plugin libraries'
            'gst-plugins-base: "base" plugin libraries'
            'gst-plugins-good: "good" plugin libraries'
            'gst-plugins-ugly: "ugly" plugin libraries')
provides=("${_name}")
conflicts=("${_name}")
source=(source::git+"${url}.git#tag=v${pkgver}")
b2sums=('69ee8b0b2ecb0402704d68d548c084cef4c767bc43c3fd002bf6586a7ef946f20e7b9e52880ea3414f6dd957ec3caf50159832d67b94c7ab3233a3761889ee8a')

build() {
  arch-meson "source" build
  meson compile -C build
}

package() {
  meson install -C build --destdir "${pkgdir}"
}
