# Maintainer: Integral <integral@member.fsf.org>
# Contributor: Julian <juliannfairfax@protonmail.com>

pkgname=flare
pkgver=0.22.1
pkgrel=1
epoch=1
pkgdesc="Chat with your friends on Signal"
url="https://gitlab.com/schmiddi-on-mobile/${pkgname}"
arch=('x86_64' 'aarch64')
license=("AGPL-3.0-or-later")
makedepends=("blueprint-compiler" "cargo" "meson")
depends=(
	'dconf'
	'gdk-pixbuf2'
	'glib2'
	'glibc'
	'gtk4'
	'gtksourceview5'
	'hicolor-icon-theme'
	'libadwaita'
	'libgcc'
	'libsecret'
	'libspelling'
	'pango'
	'protobuf'
	'sqlcipher'
)
optdepends=("feedbackd: for vibrating notifications")
source=("${url}/-/archive/${pkgver}/${pkgname}-${pkgver}.tar.gz")
sha256sums=('f49621a2c434963c4081a66c4f08630fe1d8831350fdd2ce8cf8264e80982d7a')

build() {
	export LIBSQLITE3_SYS_USE_PKG_CONFIG=1
	export CFLAGS+=" -ffat-lto-objects"
	export CARGO_PROFILE_RELEASE_LTO=true
	export CARGO_PROFILE_RELEASE_CODEGEN_UNITS=1

	arch-meson "${pkgname}-${pkgver}" build
	meson compile -C build
}

check() {
	meson test -C build --print-errorlogs
}

package() {
	meson install -C build --no-rebuild --destdir "${pkgdir}"
	install -Dm644 ${pkgname}-${pkgver}/doc/* -t "${pkgdir}/usr/share/doc/${pkgname}/"
}
