# Maintainer: Integral <integral@member.fsf.org>
# Contributor: Julian <juliannfairfax@protonmail.com>

pkgname=flare-git
_pkgname=${pkgname%-git}
pkgver=0.22.1.r2.g9ab1984
pkgrel=1
pkgdesc="Chat with your friends on Signal"
url="https://gitlab.com/schmiddi-on-mobile/${_pkgname}"
arch=('x86_64' 'aarch64')
license=("AGPL-3.0-or-later")
makedepends=("git" "blueprint-compiler" "cargo" "meson")
depends=(
	'dconf'
	'gdk-pixbuf2'
	'glib2'
	'glibc'
	'gtk4'
	'gtksourceview5'
	'hicolor-icon-theme'
	'libadwaita'
	'libgcc'
	'libsecret'
	'libspelling'
	'pango'
	'protobuf'
	'sqlcipher'
)
optdepends=("feedbackd: for vibrating notifications")
conflicts=("${_pkgname}")
provides=("${_pkgname}")
source=("git+${url}.git")
sha256sums=("SKIP")

pkgver() {
	cd "${_pkgname}/"
	git describe --long --tags --abbrev=7 | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
	export LIBSQLITE3_SYS_USE_PKG_CONFIG=1
	export CFLAGS+=" -ffat-lto-objects"
	export CARGO_PROFILE_RELEASE_LTO=true
	export CARGO_PROFILE_RELEASE_CODEGEN_UNITS=1

	arch-meson "${_pkgname}" build
	meson compile -C build
}

check() {
	meson test -C build --print-errorlogs
}

package() {
	meson install -C build --no-rebuild --destdir "${pkgdir}"
	install -Dm644 ${_pkgname}/doc/* -t "${pkgdir}/usr/share/doc/${_pkgname}/"
}
