# Maintainer: Coelacanthus <uwu@coelacanthus.name>
# Contributor: AdmiringWorm <kim.nordmo@gmail.com>
# Contributor: nirnakinho <aur at dominikbodi dot de>

pkgname=dnscontrol
pkgver=4.46.0
pkgrel=1
pkgdesc="Synchronize your DNS to multiple providers from a simple DSL"
arch=('x86_64' 'armv7h' 'aarch64')
url="https://stackexchange.github.io/$pkgname/"
license=('MIT')
depends=('glibc')
makedepends=('go')
source=("$pkgname-$pkgver.tar.gz::https://github.com/StackExchange/$pkgname/archive/v$pkgver.tar.gz")
b2sums=('f16b673dbbf8ed150a8f20bc3b78b8ebdbff2933bb37c6f959549f68d5b260a1d4d594618db242f39cf83e2e3213e28eb2ef6824473ba96190a22259bf48dea1')

prepare(){
    cd "$pkgname-$pkgver"
    mkdir -p build/
}

build() {
    cd "$pkgname-$pkgver"
    export CGO_CPPFLAGS="$CPPFLAGS"
    export CGO_CFLAGS="$CFLAGS"
    export CGO_CXXFLAGS="$CXXFLAGS"
    export CGO_LDFLAGS="$LDFLAGS"
    export GOFLAGS="-buildmode=pie -mod=readonly -modcacherw"
    go build \
        -o build \
        -ldflags "-compressdwarf=false -linkmode external"
}

package() {
    cd "$pkgname-$pkgver"
    install -Dm755 "build/$pkgname" -t "$pkgdir/usr/bin/"
    mkdir -p "$pkgdir/usr/share/bash-completion/completions/"
    build/$pkgname shell-completion bash > "$pkgdir/usr/share/bash-completion/completions/$pkgname"
    mkdir -p "$pkgdir/usr/share/zsh/site-functions/"
    build/$pkgname shell-completion zsh > "$pkgdir/usr/share/zsh/site-functions/_$pkgname"
    install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
}

# vim: set ts=4 sw=4 et:
