# Maintainer: Integral <integral@member.fsf.org>
# Contributor: txtsd <aur.archlinux@ihavea.quest>

pkgname=dissent
pkgver=0.0.37
_pkgver=$(sed 's/\./-/3' <<<${pkgver})
pkgrel=2
pkgdesc="Discord client written in go and gtk4"
arch=('x86_64' 'aarch64')
url="https://github.com/diamondburned/${pkgname}"
license=('GPL-3.0-or-later')
depends=('gtk4' 'gobject-introspection' 'libadwaita' 'gtksourceview5' 'libspelling')
makedepends=('git' 'go')
provides=("gtkcord4")
replaces=("gtkcord4")
source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/refs/tags/v${_pkgver}.tar.gz")
sha256sums=('b08ae331e5c69759eb7b9511908007fc3e9c7a28208bfa66ffbd84b6f335364a')

prepare() {
	cd "${pkgname}-${_pkgver}/"
	export GOPATH="${srcdir}"
	go mod download -modcacherw -x
	mkdir build
}

build() {
	cd "${pkgname}-${_pkgver}/"

	export CGO_CPPFLAGS="${CPPFLAGS}"
	export CGO_CFLAGS="${CFLAGS}"
	export CGO_CXXFLAGS="${CXXFLAGS}"
	export CGO_LDFLAGS="${LDFLAGS}"
	export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
	go build -o build
}

package() {
	cd "${pkgname}-${_pkgver}/"
	install -Dm755 "build/${pkgname}" -t "${pkgdir}/usr/bin/"
	install -Dm644 LICENSE.md -t "${pkgdir}/usr/share/licenses/${pkgname}/"
	sed -i '/DBusActivatable=/d' "nix/so.libdb.${pkgname}.desktop"
	install -Dm644 "nix/so.libdb.${pkgname}.desktop" -t "${pkgdir}/usr/share/applications/"
	install -Dm644 "internal/icons/hicolor/scalable/apps/so.libdb.${pkgname}.svg" -t "${pkgdir}/usr/share/icons/hicolor/scalable/apps/"
}
