# Maintainer: Marco Rubin <marco.rubin@protonmail.com>

pkgname=cpp-jwt
pkgver=1.5.1
pkgrel=10
pkgdesc="JSON Web Token library for C++"
arch=('any')
url="https://github.com/arun11299/cpp-jwt"
license=('MIT')
depends=('nlohmann-json' 'openssl')
makedepends=('cmake')
checkdepends=('gtest' 'expat')
provides=("$pkgname=$pkgver")
conflicts=($pkgname-git)
source=("$url/archive/refs/tags/v$pkgver.tar.gz")
b2sums=('4755cf2f9bb9867851b60ac9dd6952191090391353ca6b37216b094e09eed22b96374509097991334ae9cf723c5a74929fc5207786dd936745e97630a4915575')

prepare() {
    # fix outdated version
    cd $pkgname-$pkgver
    sed -i s/1.2.0/1.4.0/ CMakeLists.txt
}

build() {
    cd $pkgname-$pkgver
    cmake -B build \
		-DCMAKE_BUILD_TYPE=Release \
		-DCMAKE_INSTALL_PREFIX=/usr \
		-DCPP_JWT_BUILD_EXAMPLES=OFF \
		-DCPP_JWT_BUILD_TESTS="$CHECKFUNC" \
		-DCPP_JWT_USE_VENDORED_NLOHMANN_JSON=OFF \
		-Wno-dev
    cmake --build build
}

check() {
    cd $pkgname-$pkgver
    ctest --test-dir build
}

package() {
    cd $pkgname-$pkgver
    DESTDIR="$pkgdir" cmake --install build
    install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}
