# Maintainer: Integral <integral@member.fsf.org>
# Contributor: Evgenii Alekseev
# Contributor: Felix Yan <felixonmars@archlinux.org>
# Contributor: Manuel Schneider  <manuelschneid3r at googles mail>

pkgname=albert
pkgver=35.1.0
pkgrel=1
pkgdesc="A sophisticated standalone keyboard launcher"
arch=('x86_64')
url="https://${pkgname}launcher.github.io"
license=('LicenseRef-Albert')
depends=(
	'libqalculate'
	'python'
	'python-pip'
	'qt6-base'
	'qt6-declarative'
	'qt6-5compat'
	'qt6-scxml'
	'qt6-shadertools'
	'qt6-svg'
	'qtkeychain-qt6'
	'qcoro'
)
makedepends=('cmake' 'qt6-tools')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/${pkgname}launcher/${pkgname}/releases/download/v${pkgver}/v${pkgver}.tar.gz")
sha512sums=('a0eaadef90b0524f9e0eb6a2bd6f41e49e11846b6a0ca73ed178122aadbfd1402204a688060be18d6ede59fd07af8729604a72c218feda1f1fb600b188c12a23')

build() {
	cmake -B build \
		-S "${pkgname}" \
		-DCMAKE_BUILD_TYPE=None \
		-DCMAKE_INSTALL_PREFIX=/usr \
		-DCMAKE_INSTALL_LIBDIR=lib \
		-DCMAKE_FIND_PACKAGE_RESOLVE_SYMLINKS=ON \
		-DQHOTKEY_INSTALL=OFF

	cmake --build build
}

package() {
	DESTDIR="${pkgdir}" cmake --install build
	install -Dm644 "${pkgname}/LICENSE.md" -t "${pkgdir}/usr/share/licenses/${pkgname}/"
}
