# Maintainer: Integral <integral@member.fsf.org>
# Contributor: tarball <bootctl@gmail.com>
# Contributor: Árni Dagur <arnidg@protonmail.ch>

pkgname=xcp
pkgver=0.24.8
pkgrel=1
pkgdesc="An extended 'cp'"
arch=('i686' 'x86_64' 'armv7h' 'aarch64')
url="https://github.com/tarka/${pkgname}"
license=('GPL-3.0-only')
depends=('gcc-libs')
makedepends=('cargo')
source=("${url}/archive/${pkgname}-v${pkgver}.tar.gz")
sha256sums=('6bb62f8d9421209f1d0b6233c882bd959003042cf6f23ce255a62354b0890f8f')

prepare() {
	cd "${pkgname}-${pkgname}-v${pkgver}/"
	cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}

build() {
	cd "${pkgname}-${pkgname}-v${pkgver}/"
	cargo build --frozen --release --all-features
}

# check() {
# 	cd "${pkgname}-${pkgname}-v${pkgver}/"
# 	cargo test --frozen --all-features
# }

package() {
	cd "${pkgname}-${pkgname}-v${pkgver}/"
	install -Dm755 "target/release/${pkgname}" -t "${pkgdir}/usr/bin/"

	cd completions
	install -Dm644 "${pkgname}.bash" "$pkgdir/usr/share/bash-completion/completions/${pkgname}"
	install -Dm644 "${pkgname}.fish" -t "$pkgdir/usr/share/fish/vendor_completions.d/"
	install -Dm644 "${pkgname}.zsh" "$pkgdir/usr/share/zsh/site-functions/_${pkgname}"
}
