# Maintainer: c0gnitivefl0w
# Co-Maintainer: eldios

pkgbase=seadrive-daemon
pkgname=(seadrive-daemon python-seadrive)
pkgver=3.0.24
pkgrel=1
pkgdesc="SeaDrive daemon with FUSE interface"
arch=('aarch64' 'armv7h' 'x86_64')
url="https://github.com/haiwen/seadrive-fuse"
license=('GPL-3.0-only')
_daemon_depends=(libcrypto.so libuuid.so libsqlite3.so libevent libz.so libcurl.so
                 fuse2 libsearpc libgobject-2.0.so libglib-2.0.so
                 jansson libwebsockets.so libargon2.so)
makedepends=(git intltool python "${_daemon_depends[@]}")
source=("git+https://github.com/haiwen/seadrive-fuse#tag=v${pkgver}")
sha256sums=('f34cea6319ed577b657d71f06e521903bcfc321761d230d2dab6158ff5c872b5')

# prepare() {
#   cd seadrive-fuse
# }

build() {
  cd seadrive-fuse

  ./autogen.sh
  ./configure --prefix=/usr
  make

  make install DESTDIR="${PWD}/pkg"
}

package_seadrive-daemon() {
  depends=("${_daemon_depends[@]}")
  cd seadrive-fuse

  mkdir -p "${pkgdir}/usr/bin/"
  cp -a pkg/usr/bin/seadrive "${pkgdir}/usr/bin/seadrive"
}

package_python-seadrive() {
  depends=(python libsearpc)
  cd seadrive-fuse

  mkdir -p "${pkgdir}/usr/lib/"
  cp -a pkg/usr/lib/python* "${pkgdir}/usr/lib"
}
