# Maintainer: Gavin Luo <lunt.luo#gmail.com>
# Contributor: Felix Bühler <account at buehler dot de>
# Contributor: lvxnull <lvxnull at proton dot me>

pkgname=(nautilus-open-any-terminal
         caja-open-any-terminal)
pkgbase="${pkgname[0]}"
pkgver=0.8.3
pkgrel=1
pkgdesc="Context-menu entry for opening other terminal in nautilus"
arch=('x86_64' 'aarch64')
url="https://github.com/Stunkymonkey/nautilus-open-any-terminal"
license=("GPL-3.0-or-later")
makedepends=(make gettext)
source=("${pkgbase}-${pkgver}.tar.gz::${url}/archive/refs/tags/${pkgver}.tar.gz")
sha256sums=('3c76a022f8bd4a11e6b75632e4b3f40adf12890c04309d0a7ef9c7cc2d52144a')
install='post.install'

build() {
  cd "${pkgbase}-${pkgver}"

  make build
}

package_nautilus-open-any-terminal() {
    depends=(python-nautilus)
    cd "${pkgbase}-${pkgver}"

    make DESTDIR="${pkgdir}" PREFIX="/usr" install-nautilus
}

package_caja-open-any-terminal() {
    depends=(python-caja)
    cd "${pkgbase}-${pkgver}"

    make DESTDIR="${pkgdir}" PREFIX="/usr" install-caja
}
