# Maintainer: Balló György <ballogyor+arch at gmail dot com>
# Contributor: Dave Reisner <dreisner@archlinux.org>
# Contributor: Alexander Rødseth <rodseth@gmail.com>
# Contributor: Thomas Jost <schnouki@schnouki.net>
# Contributor: JaDa <jada@archlinux.us>
# Contributor: Joaquim Pedro <osmano807@gmail.com>
# Contributor: Jan Rüegg <rggjan@gmail.com>

pkgname=gperftools-dynamic-tls
pkgver=2.18.1
pkgrel=1
pkgdesc='Fast, multi-threaded malloc and nifty performance analysis tools'
arch=(aarch64 x86_64)
url='https://github.com/gperftools/gperftools'
license=(BSD-3-Clause)
depends=(
  glibc
  libgcc
  libstdc++
  libunwind
)
makedepends=(
  asciidoctor
  git
)
source=("git+https://github.com/gperftools/gperftools.git#tag=gperftools-$pkgver")
b2sums=(c34297c71106df8ffa7111c7f9530b25c883492f24604da45e223487ca3eaadc7a670683eff1e6a81c237573ffd347de3986e7146fb15cbcd5a0263d5cbeada3)

_prepare() {
  cd gperftools
  autoreconf -fi
}

prepare() {
  (cd gperftools
  find -type f -exec sed -i -e 's/ABSL_ATTRIBUTE_INITIAL_EXEC//g' {} \;
  find -type f -exec sed -i -e 's/__attribute__ *( *( *tls_model *( *"initial-exec" *) *) *)//g' {} \;)
  _prepare
}

build() {
  cd gperftools
  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc \
    --localstatedir=/var \
    --enable-frame-pointers \
    --enable-libunwind
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

_check() {
  cd gperftools
  make check
}

package() {
  provides+=(gperftools=$pkgver)
  conflicts+=(gperftools=$pkgver)
  cd gperftools
  make DESTDIR="$pkgdir" install
  install -Dm644 -t "$pkgdir/usr/share/licenses/gperftools/" COPYING
}
