# Maintainer: Integral <integral@member.fsf.org>

pkgname=caligula-git
_pkgname=${pkgname%-git}
pkgver=0.5.0.rc.2.r56.g84ecaad
pkgrel=1
pkgdesc="A user-friendly, lightweight TUI for disk imaging"
arch=('x86_64' 'aarch64' 'riscv64')
url="https://github.com/ifd3f/${_pkgname}"
license=('GPL-3.0-or-later')
depends=('libgcc' 'xz')
makedepends=('git' 'cargo')
conflicts=("${_pkgname}")
provides=("${_pkgname}")
source=("git+${url}.git")
sha256sums=('SKIP')
options=('!lto')

pkgver() {
	cd "${_pkgname}/"
	git describe --long --tags --abbrev=7 | sed 's/\([^-]*-g\)/r\1/;s/-/./g;s/v//'
}

prepare() {
	cd "${_pkgname}/"
	sed -i '/^xz2 =/s/"static"//' Cargo.toml

	export RUSTUP_TOOLCHAIN=stable
	cargo fetch --locked --target host-tuple
}

build() {
	cd "${_pkgname}/"
	export RUSTUP_TOOLCHAIN=stable
	export CARGO_TARGET_DIR=target
	cargo build --frozen --release --all-features
}

check() {
	cd "${_pkgname}/"
	export RUSTUP_TOOLCHAIN=stable
	cargo test --frozen --all-features
}

package() {
	cd "${_pkgname}/"
	install -Dm755 "target/release/${_pkgname}" -t "$pkgdir/usr/bin/"
	install -Dm644 README.md -t "${pkgdir}/usr/share/doc/${_pkgname}/"
}
