-- This file is part of the Wire Server implementation.
--
-- Copyright (C) 2022 Wire Swiss GmbH <opensource@wire.com>
--
-- This program is free software: you can redistribute it and/or modify it under
-- the terms of the GNU Affero General Public License as published by the Free
-- Software Foundation, either version 3 of the License, or (at your option) any
-- later version.
--
-- This program is distributed in the hope that it will be useful, but WITHOUT
-- ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
-- FOR A PARTICULAR PURPOSE. See the GNU Affero General Public License for more
-- details.
--
-- You should have received a copy of the GNU Affero General Public License along
-- with this program. If not, see <https://www.gnu.org/licenses/>.

module Spar.Sem.Utils
  ( interpretClientToIO,
    ttlErrorToSparError,
    rpcExceptionToSparError,
    idpDbErrorToSparError,
  )
where

import Cassandra as Cas
import qualified Control.Monad.Catch as Catch
import qualified Data.Text.Lazy as LText
import Imports
import Polysemy
import Polysemy.Error
import Polysemy.Final
import qualified SAML2.WebSSO as SAML
import Spar.Error
import Wire.API.User.Saml
import Wire.RpcException

-- | Run an embedded Cassandra 'Client'  in @Final IO@.
interpretClientToIO ::
  ( Member (Error SparError) r,
    Member (Final IO) r
  ) =>
  ClientState ->
  Sem (Embed Client ': r) a ->
  Sem r a
interpretClientToIO ctx = interpret $ \case
  Embed action -> withStrategicToFinal @IO $ do
    action' <- liftS $ runClient ctx action
    st <- getInitialStateS
    handler' <-
      bindS $
        throw @SparError
          . SAML.CustomError
          . SparCassandraError
          . LText.pack
          . displayException @SomeException
    pure $ action' `Catch.catch` \e -> handler' $ e <$ st

ttlErrorToSparError :: (Member (Error SparError) r) => Sem (Error TTLError ': r) a -> Sem r a
ttlErrorToSparError = mapError (SAML.CustomError . SparCassandraTTLError)

rpcExceptionToSparError :: (Member (Error SparError) r) => Sem (Error RpcException ': r) a -> Sem r a
rpcExceptionToSparError = mapError (SAML.CustomError . SparRpcException)

idpDbErrorToSparError :: (Member (Error SparError) r) => Sem (Error IdpDbError ': r) a -> Sem r a
idpDbErrorToSparError = mapError (SAML.CustomError . IdpDbError)
