## Valve
# Maintainer: Vicki Pfau <vi@endrift.com>
# Maintainer: Jeremy Whiting <jeremy.whiting@collabora.com>
## CachyOS
# Maintainer: Eric Naim <dnaim@cachyos.org>

pkgname=steamos-manager
pkgver=26.4.1
pkgrel=1
pkgdesc='SteamOS Manager daemon for running various system management tasks'
arch=('x86_64')
url='https://store.steampowered.com/steamos/'
license=('MIT')
depends=(
    'dbus'
    'gcc-libs'
    'glibc'
    'speech-dispatcher'
    'steamos-networking-tools' # For steamos-wifi-set-backend
    'systemd'
    'systemd-libs'
    'wireless_tools')  # For iwconfig
optdepends=('jupiter-hw-support: jupiter support')  # Needed for jupiter-get-als-gain, jupiter-biosupdate, steamos-format-device, steamos-trim-devices
makedepends=('git' 'cargo' 'clang')
source=("git+https://gitlab.steamos.cloud/holo/steamos-manager.git#tag=v${pkgver}"
        "support-gamescope-session-steam.patch")
sha256sums=('0191e09b05324aab8fe4dfd7e133e8e702fc1a633d29484ed0a367216ad35817'
            '7eb26772b2d6ce474ce4469816ee224bba8cd68c6847487b14e09865194238d8')
install='steamos-manager.install'

prepare() {
    cd "${pkgname}"

    # MSI Claw 8 EX support
    git cherry-pick -n 7de5caad5e4d4f3bd9f179ddd7acc94e1cb2d677

    patch -Np1 -i ../support-gamescope-session-steam.patch

    cargo fetch --locked --target "x86_64-unknown-linux-gnu"
}

build() {
    cd "${pkgname}"
    make build
}

package () {
    cd "${pkgname}"
    make install DESTDIR="${pkgdir}"
}
