# Maintainer: Eric Naim <dnaim@cachyos.org>

pkgname=gamescope-session-cachyos
pkgver=1.1.6
pkgrel=1
pkgdesc="Steam Big Picture session based on gamescope from SteamOS"
arch=('any')
url="https://github.com/CachyOS/gamescope-session"
license=('MIT') # this is what Valve put on their gamescope package
depends=(
    'bash'
    'coreutils'
    'dbus'
    'gamescope'
    'jupiter-hw-support>=20260211.1-2'
    'python'
    'steam'
    'systemd'
    'util-linux'
)
makedepends=('git')
optdepends=(
    'ibus: Multilingual input support'
    'galileo-mura: Mura compensation for Steam Deck OLED'
    'mangohud: Mangoapp'
)
provides=('gamescope-session-git' 'gamescope-session-steam-git')
conflicts=('gamescope-session-git' 'gamescope-session-steam-git')
source=("${pkgname}::git+${url}.git#tag=${pkgver}")
sha256sums=('6ade88ca4c6e66713010ccfcbc57be82037721f2ac13486b20a14f67267a7da1')

prepare() {
    cd "${pkgname}"
    git cherry-pick -n aea6a6cced80
}

package() {
    cd "${pkgname}"
    cp -a usr/ "${pkgdir}/usr"
}
