# Maintainer: Vladislav Nepogodin <nepogodin.vlad@gmail.com>

pkgname=cachyos-cli-installer-new
_pkgname=New-Cli-Installer
pkgver=0.12.4
pkgrel=1
pkgdesc='New CLI installer for CachyOS'
arch=(x86_64)
license=(GPL-3.0-or-later)
url="https://github.com/cachyos/new-cli-installer"
depends=('fzf' 'gawk' 'chwd' 'cachyos-rate-mirrors' 'curl' 'coreutils' 'util-linux' 'gptfdisk' 'cryptsetup')
makedepends=('cmake' 'ninja' 'git' 'lld' 'clang' 'llvm')
source=("$pkgname::git+$url.git#tag=${pkgver}?signed")
sha256sums=('432fce52877b2d525d8c22e3966b7bc23f7791d4df3121826eba32f35edaf34f')
validpgpkeys=(
  'B1B70BB1CD56047DEF31DE2EB62C3D10C54D5DA9'  # Vladislav Nepogodin <nepogodin.vlad@gmail.com>
)

build() {
  cd "$srcdir/$pkgname"

  CFLAGS=${CFLAGS/-Wp,-D_GLIBCXX_ASSERTIONS}
  CXXFLAGS=${CXXFLAGS/-Wp,-D_GLIBCXX_ASSERTIONS}

  # we are building with llvm stack here
  export AR=llvm-ar
  export CC=clang
  export CXX=clang++
  export NM=llvm-nm
  export RANLIB=llvm-ranlib

  cmake -S . -Bbuild \
        -GNinja \
        -DCMAKE_BUILD_TYPE=Release \
        -DCMAKE_INSTALL_PREFIX=/usr \
        -DCMAKE_INSTALL_LIBDIR=lib \
        -DENABLE_DEVENV=OFF \
        -DGUCC_BUILD_TOOLS=ON \
        -DCOS_BUILD_STATIC=ON
  cmake --build build
}

package() {
  cd "$srcdir/$pkgname"
  DESTDIR="${pkgdir}" cmake --build build --target install

  install -Dm644 net-profiles.toml "$pkgdir/var/lib/cachyos-installer/net-profiles.toml"
  install -Dm644 server-profiles.toml "$pkgdir/var/lib/cachyos-installer/server-profiles.toml"
}

# vim:set sw=2 sts=2 et:
