# Maintainer: Robin Candau <antiz@archlinux.org>

pkgname=cachy-update
pkgver=4.1.3
pkgrel=1
pkgdesc="An interactive update notifier & applier that assists you with important pre / post update tasks"
url="https://github.com/CachyOS/cachy-update"
arch=('x86_64' 'aarch64')
license=('GPL-3.0-or-later')
depends=('bash' 'systemd' 'pacman' 'pacman-contrib' 'archlinux-contrib' 'curl' 'fakeroot' 'util-linux'
         'htmlq' 'diffutils' 'hicolor-icon-theme' 'glibc' 'libgcc' 'glib2' 'xdg-utils')
makedepends=('cargo' 'scdoc' 'git')
checkdepends=('bats')
conflicts=('arch-update')
optdepends=('paru: AUR Packages support'
            'yay: AUR Packages support'
            'pikaur: AUR Packages support'
            'flatpak: Flatpak Packages support'
            'libnotify: Desktop notifications support on new available updates'
            'alhp-utils: Check for ALHP build queue or outdated mirrors'
            'vim: Default diff program for pacdiff'
            'neovim: Default diff program for pacdiff if EDITOR=nvim'
            'sudo: Privilege elevation'
            'sudo-rs: Privilege elevation'
            'opendoas: Privilege elavation')
source=("git+https://github.com/CachyOS/cachy-update#commit=2f4a7261ef6e71a11d34fb63e516786b8cbc993f")
sha256sums=('982c4b65e024d487fc4a4af368eebbe31d87a0371f76a4da2cb5d90abffe4682')

prepare() {
    cd "${pkgname}"
    make clean
}

build() {
    cd "${pkgname}"
    make
}

check() {
    cd "${pkgname}"
    make test
}

package() {
    cd "${pkgname}"
    make PREFIX=/usr DESTDIR="${pkgdir}" install

    install -Dm 644 res/desktop/arch-update-tray.desktop "${pkgdir}/etc/xdg/autostart/arch-update-tray.desktop"
    ln -s arch-update "${pkgdir}/usr/bin/${pkgname}"
}
