# Maintainer: aur.chaotic.cx

_pkgname="zrythm"
pkgname="$_pkgname"
pkgver=1.0.0
pkgrel=3
pkgdesc='Highly automated and intuitive digital audio workstation'
url="https://gitlab.zrythm.org/zrythm/zrythm"
license=('AGPL-3.0-or-later')
arch=('x86_64')

depends=(
  'dconf'
  'fftw'
  'fluidsynth'
  'graphene'
  'graphviz'
  'gtk4'
  'gtksourceview5'
  'libadwaita'
  'libbacktrace'
  'libcyaml'
  'libpanel'
  'libsoxr'
  'libxrandr'
  'rtaudio'
  'rtmidi'
  'rubberband'
  'sdl2'
  'vamp-plugin-sdk'
  'xxhash'
  'yyjson'
  'zix'

  # AUR
  'carla>=2.5.10.r498'
  'lsp-dsp-lib'
)
makedepends=(
  'boost'
  'cmake'
  'git'
  'glib2-devel'
  'help2man'
  'lilv' # lv2apply is not installed
  'meson'
  'ruby-sass'
  'sassc'
)
optdepends=(
  'realtime-privileges: allow memory locking'
)

_pkgsrc="$_pkgname-$pkgver"
_pkgext="tar.xz"
source=("https://www.zrythm.org/releases/$_pkgsrc.$_pkgext")
sha256sums=('d143a0a17066b50db8a6db875d2699c9e5b70f1bbe18db00fee034840144fede')

build() {
  local _meson_args=(
    -Dcarla=enabled
    -Dcarla_binaries_dir=/usr/lib/carla
    -Dcompletions=true
    -Dgraphviz=enabled
    -Dopus=true
    -Dportaudio=enabled
    -Drtaudio=enabled
    -Drtmidi=enabled
    -Dsdl=enabled
    -Dsoundio=disabled

    -Dcheck_updates=false
    -Ddebug=false
    -Dmanpage=true
    -Dstatic_deps=false
  )

  arch-meson "${_meson_args[@]}" "$_pkgsrc" build
  meson compile -C build
}

package() {
  meson install -C build --destdir="$pkgdir"
  rm -rf "$pkgdir"{/usr/include/zix-0/,/usr/lib/pkgconfig/zix-0.pc}
}
