# Maintainer: aur.chaotic.cx

_pkgname="vicinae"
pkgname="$_pkgname"
pkgver=0.24.0
pkgrel=3
pkgdesc="A focused launcher for your desktop"
url="https://github.com/vicinaehq/vicinae"
license=('GPL-3.0-or-later')
arch=('x86_64')

depends=(
  'cmark-gfm'
  'hicolor-icon-theme'
  'layer-shell-qt'
  'libcrypto.so' # openssl
  'libqalculate'
  'libwayland-client.so' # wayland
  'nodejs'               # for extensions
  'qt6-base'
  'qt6-declarative'
  'qt6-svg'
  'qtkeychain-qt6'
  'syntax-highlighting'
)
makedepends=(
  'cmake'
  'glaze'
  'ninja'
  'npm'
  'qt6-shadertools'
  'qt6-tools'
  'rapidfuzz-cpp'
  'vulkan-headers'
)

_pkgsrc="$_pkgname-$pkgver"
_pkgext="tar.gz"
source=("$_pkgsrc.$_pkgext"::"$url/archive/refs/tags/v$pkgver.$_pkgext")
sha256sums=('8293ae0b62163931befe2bbefce879b708f6d6893b139dcf1fc5c7f19117f861')

build() {
  local _cmake_options=(
    -B build
    -S "$_pkgsrc"
    -G Ninja
    -DCMAKE_BUILD_TYPE=None
    -DCMAKE_INSTALL_PREFIX='/usr'
    -DCMAKE_INSTALL_LIBEXECDIR='lib'
    -Wno-author

    -DUSE_SYSTEM_CMARK_GFM=ON
    -DUSE_SYSTEM_GLAZE=ON
    -DUSE_SYSTEM_KF6=ON
    -DUSE_SYSTEM_LAYER_SHELL=ON
    -DUSE_SYSTEM_QT_KEYCHAIN=ON

    -DVICINAE_PROVENANCE="chaotic-aur"
    -DVICINAE_GIT_TAG="v${pkgver}"
    -DVICINAE_GIT_COMMIT_HASH=$(
      git ls-remote "$url.git" \
        | grep -Pom1 "^\\S{7,7}(?=\\S+\\s+refs/tags/v$pkgver\$)"
    )
  )

  cmake "${_cmake_options[@]}"
  cmake --build build
}

package() {
  DESTDIR="$pkgdir" cmake --install build
}
