# Maintainer: aur.chaotic.cx

_pkgname="trustedqsl"
pkgname="$_pkgname"
pkgver=2.8.6
pkgrel=1
pkgdesc="QSO log signing data for the ARRL Logbook of The World (LoTW)"
url="https://www.arrl.org/tqsl"
license=('LicenseRef-ARRL')
arch=('x86_64')

depends=(
  'wxwidgets-gtk3'
)
makedepends=(
  'cmake'
  'desktop-file-utils'
  'libxxf86vm'
  'ninja'
)
optdepends=(
  'hamradio-menus'
)

_pkgsrc="tqsl-$pkgver"
_pkgext="tar.gz"
source=("$_pkgsrc.$_pkgext"::"http://www.arrl.org/tqsl/$_pkgsrc.$_pkgext")
sha256sums=('182e5f2ac35a3db8b409b45d96505e6bd265ae4668ed064754209c4b8e7bdf37')

build() {
  local _cmake_options=(
    -B build
    -S "$_pkgsrc"
    -G Ninja
    -DCMAKE_BUILD_TYPE=None
    -DCMAKE_INSTALL_PREFIX='/usr'
    -DwxWidgets_CONFIG_EXECUTABLE='/usr/bin/wx-config'
    -DwxWidgets_wxrc_EXECUTABLE='/usr/bin/wxrc'
    -Wno-author
  )

  cmake "${_cmake_options[@]}"
  cmake --build build
}

package() {
  DESTDIR="$pkgdir" cmake --install build
  install -Dm644 "$_pkgsrc/LICENSE.txt" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  desktop-file-edit --set-name=TrustedQSL "$pkgdir/usr/share/applications/org.arrl.trustedqsl.desktop"
}
