# Contributor: Johannes Dewender  arch at JonnyJD dot net

pkgname=python-rtslib-fb
_pkgname=rtslib-fb
pkgver=2.2.4
pkgrel=1
pkgdesc="free branch version of the LIO target API"
arch=('any')
url="https://github.com/open-iscsi/${_pkgname}"
license=('Apache')
options=()
depends=('python' 'python-pyudev')
makedepends=('git' 'python' 'python-build' 'python-installer')
provides=('python-rtslib')
conflicts=('python-rtslib')
source=("git+${url}.git#tag=v${pkgver}")
sha512sums=('61d324ce35575c722fa003f0b8a375d8080c58aad0c150349b4761048ca6d0793a44faac50f2f0a0796bc314f7798f1b231e8513233e58269590d256041ab7f0')

_pydep1() {
  if which python > /dev/null 2>&1; then
    python -c 'import sys; major, minor = sys.version.split(".")[:2]; print(f"python>={major}.{minor}")'
  else
    echo "python"
  fi
}

_pydep2() {
  if which python > /dev/null 2>&1; then
    python -c 'import sys; major, minor = sys.version.split(".")[:2]; print(f"python<{major}.{int(minor)+1}")'
  else
    echo "python"
  fi
}

build() {
  cd "$srcdir/$_pkgname"

  python -m build
}

package() {
  depends=("$(_pydep1)" "$(_pydep2)" "${depends[@]:1}")
  cd "$srcdir/$_pkgname"
  python -m installer --destdir="${pkgdir}" dist/*.whl
  ln -s rtslib "${pkgdir}/$(python3 -c 'import sysconfig; print(sysconfig.get_paths()["purelib"])')/rtslib_fb"
  install -D -m0644 "systemd/target.service" "$pkgdir/usr/lib/systemd/system/target.service"
}

# vim:set ts=2 sw=2 et:
