# Maintainer: Guido Iodice <guido.iodice@gmail.com>
# Contributor: Zren <zrenfire@gmail.com>

_pkgname="material-kwin-decoration"
pkgname="${_pkgname}-git"
pkgver=r713.3d27f39
pkgrel=1
pkgdesc="Material-ish window decoration for KWin, with LIM (Locally Integrated Menu) support"
url="https://github.com/guiodic/material-decoration"
license=('GPL-2.0-or-later')
arch=('x86_64')

depends=(kwin)
makedepends=(
  cmake
  extra-cmake-modules
  git
  vulkan-headers
)
optdepends=(
  'plasma-x11-session: for X11 support'
  'appmenu-gtk-module: gtk app support (X11)'
  'appmenu-gtk-module-wayland: gtk app support (Wayland)'
  'kwin-minimize2tray-git: Minimize to tray on Close long press'
  'kwin-effects-better-blur-dx: strongly recommended on Wayland if you set Titlebar Opacity < 100%'
)

provides=("$_pkgname")
conflicts=("$_pkgname")

_pkgsrc="$_pkgname"
source=("$_pkgsrc"::"git+$url.git")
sha256sums=('SKIP')

pkgver() {
  cd "$_pkgsrc"
  printf "r%s.%s" \
    "$(git rev-list --count HEAD)" \
    "$(git rev-parse --short=7 HEAD)"
}

build() {
  local _cmake_options=(
    -B build
    -S "$_pkgsrc"
    -Wno-dev
  )

  cmake "${_cmake_options[@]}"
  cmake --build build
}

package() {
  DESTDIR="${pkgdir:?}" cmake --install build
}
