# Maintainer: aur.chaotic.cx

_pkgname="llama-cpp"
pkgname="$_pkgname-git"
pkgver=b10234.r1.g221f0f6
pkgrel=1
pkgdesc="LLM inference in C/C++"
url="https://github.com/ggml-org/llama.cpp"
license=('MIT')
arch=('x86_64')

depends=(
  'ggml'
  'openssl'
)
makedepends=(
  'cmake'
  'git'
  'ninja'
  'npm'
)

provides=("$_pkgname")
conflicts=("$_pkgname")

_pkgsrc="$_pkgname"
source=("$_pkgsrc"::"git+$url.git")
sha256sums=('SKIP')

pkgver() {
  cd "$_pkgsrc"
  git describe --long --tags --abbrev=7 --exclude='*[a-zA-Z][a-zA-Z]*' --match='b*' \
    | sed -E 's/([^-]*-g)/r\1/;s/-/./g'
}

build() (
  local _cmake_options=(
    -B build
    -S "$_pkgsrc"
    -G Ninja
    -DCMAKE_BUILD_TYPE=None
    -DCMAKE_INSTALL_PREFIX='/usr'
    -DBUILD_SHARED_LIBS=ON
    -Wno-author

    -DLLAMA_BUILD_APP=OFF
    -DLLAMA_BUILD_EXAMPLES=ON
    -DLLAMA_BUILD_SERVER=ON
    -DLLAMA_BUILD_TESTS=OFF
    -DLLAMA_BUILD_TOOLS=ON
    -DLLAMA_BUILD_UI=ON
    -DLLAMA_USE_SYSTEM_GGML=ON

  )
  cmake "${_cmake_options[@]}"
  cmake --build build
)

package() {
  DESTDIR="$pkgdir" cmake --install build
  install -Dm644 "$_pkgsrc/LICENSE" -t "$pkgdir/usr/share/licenses/$pkgname/"

  # unwanted files
  rm -rf "$pkgdir/usr/bin"/test*
}
