# Maintainer: aur.chaotic.cx

_pkgname="kindleunpack"
pkgname="$_pkgname-git"
pkgver=0.84.r0.gbf0ca6e
pkgrel=2
pkgdesc="Extract text, images, and metadata from Kindle and Mobi files"
url="https://github.com/kevinhendricks/KindleUnpack"
license=('GPL-3.0-only')
arch=('any')

depends=(
  'python'
  'tk'
)
makedepends=(
  'git'
  'python-build'
  'python-installer'
  'python-setuptools'
  'python-wheel'
)

provides=("$_pkgname")
conflicts=("$_pkgname")

_pkgsrc="$_pkgname"
source=(
  "$_pkgname"::"git+$url.git"
  "Installing-with-setuptools.patch"
)
sha256sums=(
  'SKIP'
  '4c4eb18f9716875d90cf6c6b781ece9cbb316e2dcecebd2e89caec142bd25505'
)

prepare() {
  local src
  for src in "${source[@]}"; do
    src="${src%%::*}"
    src="${src##*/}"
    src="${src%.zst}"
    if [[ $src == *.patch ]]; then
      printf '\nApplying patch: %s\n' "$src"
      patch -d "$_pkgsrc" -Np1 -F100 -i "${srcdir:?}/$src"
    fi
  done
}

pkgver() {
  cd "$_pkgsrc"
  git describe --long --tags --abbrev=7 --match='v[0-9][0-9][0-9]' \
    | sed -E 's/^[^0-9]*([0-9])([0-9])/\1.\2/;s/([^-]*-g)/r\1/;s/-/./g'
}

build() {
  cd "$_pkgsrc"
  python -m build --wheel --no-isolation --skip-dependency-check
}

package() {
  cd "$_pkgsrc"
  python -m installer --destdir="$pkgdir" dist/*.whl
}
