# Maintainer: Patrick Northon <northon_patrick3@yahoo.ca>
# Contributor: Levente Polyak <anthraxx[at]archlinux[dot]org>
# Contributor: Frederik Schwan <freswa at archlinux dot org>
# Contributor: Guillaume ALAUX <guillaume@archlinux.org>

# TODO add test, see about packaging jtreg and using it here

pkgbase=java24-openjdk
pkgname=(
  jdk24-openjdk
  jre24-openjdk
  jre24-openjdk-headless
  openjdk24-doc
  openjdk24-src
)
# on a majorver change, don't forget to update the misc files that come along this PKGBUILD
_majorver=24
_minorver=0
_securityver=2
_updatever=12
pkgver=${_majorver}.${_minorver}.${_securityver}.u${_updatever}
# pkgver=${_majorver}.u${_updatever}
pkgrel=3
_git_tag=jdk-${_majorver}.${_minorver}.${_securityver}+${_updatever}
# _git_tag=jdk-${_majorver}+${_updatever}
arch=('x86_64')
url='https://openjdk.java.net/'
license=('LicenseRef-Java')
makedepends=(
  "java-environment>=23"
  alsa-lib
  bash
  cpio
  freetype2
  libgcc
  giflib
  glibc
  graphviz
  harfbuzz
  lcms2
  libcups
  libelf
  libjpeg-turbo
  libnet
  libpng
  libx11
  libxext
  libxrandr
  libxrender
  libxt
  libxtst
  pandoc
  unzip
  zip
)
optdepends=(
  'gvfs: open links e.g. hyperlinks'
)
source=(
  https://github.com/openjdk/jdk${_majorver}u/archive/${_git_tag}.tar.gz
  freedesktop-24-java.desktop
  freedesktop-24-jconsole.desktop
  freedesktop-24-jshell.desktop
  'https://github.com/openjdk/jdk25u/commit/38bb8adf4f632b08af15f2d8530b35f05f86a020.patch'
)
sha256sums=('947087e85c4222f25e1b9a707cea89b04c00a0a9eb79ded489f0bab92ea42beb'
  'ad877c65ac7e752369407f4af8fd9a20a377f2a55e62224e44df1c9a9af407a3'
  '3544325a47fd7f9854d2ee4a0a6eb17d729af20889b641838aceb58837fb2d58'
  '5d6beeeac3d097b2c85099fceeba4a5e48e07fd286ad438f57936ebcd7bfbdbb'
  'a3698606cd871bd9a2b2fa1cd62eb18d27394ee536747334818502e21d41823c')

case "${CARCH}" in
  x86_64) _JARCH='x86_64' ;;
  i686) _JARCH='x86' ;;
  riscv64) _JARCH='riscv64' ;;
esac

_jvmdir=/usr/lib/jvm/java-${_majorver}-openjdk
_jdkdir=jdk${_majorver}u-${_git_tag//+/-}
_imgdir=${_jdkdir}/build/linux-${_JARCH}-server-release/images

_nonheadless=(
  lib/libawt_xawt.so
  lib/libjawt.so
  lib/libjsound.so
  lib/libsplashscreen.so
)

_commondeps=(
  'java-runtime-common>=3'
  ca-certificates-utils
  freetype2
  libgcc
  glibc
  harfbuzz
  lcms2
  libfreetype.so
  libharfbuzz.so
  libjpeg.so
  libjpeg-turbo
  liblcms2.so
  libnet
  nss
)

prepare() {
  cd ${_jdkdir}
  patch -p1 -i "${srcdir}/38bb8adf4f632b08af15f2d8530b35f05f86a020.patch"
}

build() {
  cd ${_jdkdir}

  # remove -j from MAKEFLAGS to prevent build fail
  local MAKEFLAG_J=$(echo ${MAKEFLAGS} | sed -En 's/.*-j([0-9]+).*/\1/p')
  export MAKEFLAGS=${MAKEFLAGS/-j${MAKEFLAG_J}/}

  # Avoid optimization of HotSpot to be lowered from O3 to O2
  local _CFLAGS="${CFLAGS//-O2/-O3} ${CPPFLAGS} -fcommon"
  local _CXXFLAGS="${CXXFLAGS//-O2/-O3} ${CPPFLAGS} -fcommon"
  local _LDFLAGS=${LDFLAGS}
  if [[ ${CARCH} = i686 ]]; then
    echo "Removing '-fno-plt' from CFLAGS and CXXFLAGS to prevent build fail with this architecture"
    _CFLAGS=${_CFLAGS/-fno-plt/}
    _CXXFLAGS=${_CXXFLAGS/-fno-plt/}
  fi

  # TODO: Should be rechecked for the next releases
  # compiling with -fexceptions leads to:
  # /usr/bin/ld: /build/java-openjdk/src/jdk17u-jdk-17.0.3-2/build/linux-x86_64-server-release/hotspot/variant-server/libjvm/objs/zPhysicalMemory.o: in function `ZList<ZMemory>::~ZList()':
  # /build/java-openjdk/src/jdk17u-jdk-17.0.3-2/src/hotspot/share/gc/z/zList.hpp:54: undefined reference to `ZListNode<ZMemory>::~ZListNode()'
  # collect2: error: ld returned 1 exit status
  _CFLAGS=${_CFLAGS/-fexceptions/}
  _CXXFLAGS=${_CXXFLAGS/-fexceptions/}

  # CFLAGS, CXXFLAGS and LDFLAGS are ignored as shown by a warning
  # in the output of ./configure unless used like such:
  #  --with-extra-cflags="${CFLAGS}"
  #  --with-extra-cxxflags="${CXXFLAGS}"
  #  --with-extra-ldflags="${LDFLAGS}"
  # See also paragraph "Configure Control Variables from "jdk${_majorver}-${_git_tag}/common/doc/building.md
  unset CFLAGS
  unset CXXFLAGS
  unset LDFLAGS

  if check_option "lto" "y"; then
    jvm_features="zgc,shenandoahgc,link-time-opt"
  else
    jvm_features="zgc,shenandoahgc"
  fi

  bash configure \
    --with-version-string="${_majorver}.${_minorver}.${_securityver}" \
    --with-stdc++lib=dynamic \
    --with-extra-cflags="${_CFLAGS}" \
    --with-extra-cxxflags="${_CXXFLAGS}" \
    --with-extra-ldflags="${_LDFLAGS}" \
    --with-libjpeg=system \
    --with-giflib=system \
    --with-libpng=system \
    --with-lcms=system \
    --with-zlib=system \
    --with-harfbuzz=system \
    --with-jvm-features="${jvm_features}" \
    --with-native-debug-symbols=internal \
    --enable-unlimited-crypto \
    --disable-warnings-as-errors \
    --with-vendor-name="Arch Linux"

  make images legacy-jre-image docs

  # https://bugs.openjdk.java.net/browse/JDK-8173610
  find "${srcdir}/${_imgdir}" -iname '*.so' -exec chmod +x {} \;
}

check() {
  cd ${_jdkdir}
  # TODO package jtreg
  # make -k check
}

package_jre24-openjdk-headless() {
  pkgdesc="OpenJDK Java ${_majorver} headless runtime environment"
  depends=(
    "${_commondeps[@]}"
  )
  optdepends=(
    'java-rhino: for some JavaScript support'
  )
  provides=(
    "java-runtime-headless=${_majorver}"
    "java-runtime-headless-openjdk=${_majorver}"
    "jre${_majorver}-openjdk-headless=${pkgver}-${pkgrel}"
  )
  conflicts=(
    jdk${_majorver}-openjdk
    jre${_majorver}-openjdk
  )
  backup=(
    etc/${pkgbase}/logging.properties
    etc/${pkgbase}/management/jmxremote.access
    etc/${pkgbase}/management/jmxremote.password.template
    etc/${pkgbase}/management/management.properties
    etc/${pkgbase}/net.properties
    etc/${pkgbase}/security/java.policy
    etc/${pkgbase}/security/java.security
    etc/${pkgbase}/security/policy/README.txt
    etc/${pkgbase}/security/policy/limited/default_US_export.policy
    etc/${pkgbase}/security/policy/limited/default_local.policy
    etc/${pkgbase}/security/policy/limited/exempt_local.policy
    etc/${pkgbase}/security/policy/unlimited/default_US_export.policy
    etc/${pkgbase}/security/policy/unlimited/default_local.policy
    etc/${pkgbase}/sound.properties
  )
  install=install_jre-openjdk-headless.sh

  cd ${_imgdir}/jre

  install -dm 755 "${pkgdir}${_jvmdir}"

  cp -a bin lib \
    "${pkgdir}${_jvmdir}"

  for f in "${_nonheadless[@]}"; do
    rm "${pkgdir}${_jvmdir}/${f}"
  done

  # Conf
  install -dm 755 "${pkgdir}/etc"
  cp -r conf "${pkgdir}/etc/${pkgbase}"
  ln -s /etc/${pkgbase} "${pkgdir}/${_jvmdir}/conf"

  # Legal
  install -dm 755 "${pkgdir}/usr/share/licenses"
  cp -r legal "${pkgdir}/usr/share/licenses/${pkgbase}"
  ln -s ${pkgbase} "${pkgdir}/usr/share/licenses/${pkgname}"
  ln -s /usr/share/licenses/${pkgbase} "${pkgdir}/${_jvmdir}/legal"

  # Man pages
  for f in bin/*; do
    f=$(basename "${f}")
    _man=../jdk/man/man1/"${f}.1"
    test -f "${_man}" && install -Dm 644 "${_man}" "${pkgdir}/usr/share/man/man1/${f}-openjdk${_majorver}.1"
  done
  ln -s /usr/share/man "${pkgdir}/${_jvmdir}/man"

  # Link JKS keystore from ca-certificates-utils
  rm -f "${pkgdir}${_jvmdir}/lib/security/cacerts"
  ln -sf /etc/ssl/certs/java/cacerts "${pkgdir}${_jvmdir}/lib/security/cacerts"
}

package_jre24-openjdk() {
  pkgdesc="OpenJDK Java ${_majorver} full runtime environment"
  depends=(
    "${_commondeps[@]}"
    giflib
    libgif.so
    libpng
  )
  optdepends=(
    'alsa-lib: for basic sound support'
    'gtk3: for the Gtk+ 3 look and feel - desktop usage'
  )
  provides=(
    "java-runtime=${_majorver}"
    "java-runtime-openjdk=${_majorver}"
    "jre${_majorver}-openjdk=${pkgver}-${pkgrel}"
    "java-runtime-headless=${_majorver}"
    "java-runtime-headless-openjdk=${_majorver}"
    "jre${_majorver}-openjdk-headless=${pkgver}-${pkgrel}"
  )
  conflicts=(
    jdk${_majorver}-openjdk
    jre${_majorver}-openjdk-headless
  )
  backup=(
    etc/${pkgbase}/logging.properties
    etc/${pkgbase}/management/jmxremote.access
    etc/${pkgbase}/management/jmxremote.password.template
    etc/${pkgbase}/management/management.properties
    etc/${pkgbase}/net.properties
    etc/${pkgbase}/security/java.policy
    etc/${pkgbase}/security/java.security
    etc/${pkgbase}/security/policy/README.txt
    etc/${pkgbase}/security/policy/limited/default_US_export.policy
    etc/${pkgbase}/security/policy/limited/default_local.policy
    etc/${pkgbase}/security/policy/limited/exempt_local.policy
    etc/${pkgbase}/security/policy/unlimited/default_US_export.policy
    etc/${pkgbase}/security/policy/unlimited/default_local.policy
    etc/${pkgbase}/sound.properties
  )
  install=install_jre-openjdk.sh

  cd ${_imgdir}/jre

  install -dm 755 "${pkgdir}${_jvmdir}"

  cp -a bin lib \
    "${pkgdir}${_jvmdir}"

  for f in "${_nonheadless[@]}"; do
    install -Dm 755 ${f} "${pkgdir}${_jvmdir}/${f}"
  done

  # Conf
  install -dm 755 "${pkgdir}/etc"
  cp -r conf "${pkgdir}/etc/${pkgbase}"
  ln -s /etc/${pkgbase} "${pkgdir}/${_jvmdir}/conf"

  # Legal
  install -dm 755 "${pkgdir}/usr/share/licenses"
  cp -r legal "${pkgdir}/usr/share/licenses/${pkgbase}"
  ln -s ${pkgbase} "${pkgdir}/usr/share/licenses/${pkgname}"
  ln -s /usr/share/licenses/${pkgbase} "${pkgdir}/${_jvmdir}/legal"

  # Man pages
  for f in bin/*; do
    f=$(basename "${f}")
    _man=../jdk/man/man1/"${f}.1"
    test -f "${_man}" && install -Dm 644 "${_man}" "${pkgdir}/usr/share/man/man1/${f}-openjdk${_majorver}.1"
  done
  ln -s /usr/share/man "${pkgdir}/${_jvmdir}/man"

  # Link JKS keystore from ca-certificates-utils
  rm -f "${pkgdir}${_jvmdir}/lib/security/cacerts"
  ln -sf /etc/ssl/certs/java/cacerts "${pkgdir}${_jvmdir}/lib/security/cacerts"

  # Desktop files
  for f in java; do
    install -Dm 644 \
      "${srcdir}/freedesktop-24-${f}.desktop" \
      "${pkgdir}/usr/share/applications/${f}-${pkgbase}.desktop"
  done
}

package_jdk24-openjdk() {
  pkgdesc="OpenJDK Java ${_majorver} development kit"
  depends=(
    "${_commondeps[@]}"
    'java-environment-common=3'
    ca-certificates-utils
    freetype2
    harfbuzz
    hicolor-icon-theme
    lcms2
    libelf
    libfreetype.so
    libgif.so
    libharfbuzz.so
    libjpeg.so
    libjpeg-turbo
    liblcms2.so
    libnet
    libpng
    nss
  )
  optdepends=(
    'java-rhino: for some JavaScript support'
    'alsa-lib: for basic sound support'
    'gtk3: for the Gtk+ 3 look and feel - desktop usage'
  )
  provides=(
    "java-environment=${_majorver}"
    "java-environment-openjdk=${_majorver}"
    "jdk${_majorver}-openjdk=${pkgver}-${pkgrel}"
    "java-runtime=${_majorver}"
    "java-runtime-openjdk=${_majorver}"
    "jre${_majorver}-openjdk=${pkgver}-${pkgrel}"
    "java-runtime-headless=${_majorver}"
    "java-runtime-headless-openjdk=${_majorver}"
    "jre${_majorver}-openjdk-headless=${pkgver}-${pkgrel}"
  )
  conflicts=(
    jre${_majorver}-openjdk
    jre${_majorver}-openjdk-headless
  )
  backup=(
    etc/${pkgbase}/logging.properties
    etc/${pkgbase}/management/jmxremote.access
    etc/${pkgbase}/management/jmxremote.password.template
    etc/${pkgbase}/management/management.properties
    etc/${pkgbase}/net.properties
    etc/${pkgbase}/security/java.policy
    etc/${pkgbase}/security/java.security
    etc/${pkgbase}/security/policy/README.txt
    etc/${pkgbase}/security/policy/limited/default_US_export.policy
    etc/${pkgbase}/security/policy/limited/default_local.policy
    etc/${pkgbase}/security/policy/limited/exempt_local.policy
    etc/${pkgbase}/security/policy/unlimited/default_US_export.policy
    etc/${pkgbase}/security/policy/unlimited/default_local.policy
    etc/${pkgbase}/sound.properties
  )
  install=install_jdk-openjdk.sh

  cd ${_imgdir}/jdk

  install -dm 755 "${pkgdir}${_jvmdir}"

  cp -a bin demo include jmods lib release "${pkgdir}${_jvmdir}"

  rm "${pkgdir}${_jvmdir}/lib/src.zip"

  # Conf
  install -dm 755 "${pkgdir}/etc"
  cp -r conf "${pkgdir}/etc/${pkgbase}"
  ln -s /etc/${pkgbase} "${pkgdir}/${_jvmdir}/conf"

  # Legal
  install -dm 755 "${pkgdir}/usr/share/licenses"
  cp -r legal "${pkgdir}/usr/share/licenses/${pkgbase}"
  ln -s ${pkgbase} "${pkgdir}/usr/share/licenses/${pkgname}"
  ln -s /usr/share/licenses/${pkgbase} "${pkgdir}/${_jvmdir}/legal"

  # Man pages
  for f in bin/*; do
    f=$(basename "${f}")
    _man=../jdk/man/man1/"${f}.1"
    test -f "${_man}" && install -Dm 644 "${_man}" "${pkgdir}/usr/share/man/man1/${f}-openjdk${_majorver}.1"
  done
  ln -s /usr/share/man "${pkgdir}/${_jvmdir}/man"

  # Link JKS keystore from ca-certificates-utils
  rm -f "${pkgdir}${_jvmdir}/lib/security/cacerts"
  ln -sf /etc/ssl/certs/java/cacerts "${pkgdir}${_jvmdir}/lib/security/cacerts"

  # Icons
  for s in 16 24 32 48; do
    install -Dm 644 \
      "${srcdir}/${_jdkdir}/src/java.desktop/unix/classes/sun/awt/X11/java-icon${s}.png" \
      "${pkgdir}/usr/share/icons/hicolor/${s}x${s}/apps/java${_majorver}-openjdk.png"
  done

  # Desktop files
  for f in jconsole java jshell; do
    install -Dm 644 \
      "${srcdir}/freedesktop-24-${f}.desktop" \
      "${pkgdir}/usr/share/applications/${f}-${pkgbase}.desktop"
  done
}

package_openjdk24-src() {
  pkgdesc="OpenJDK Java ${_majorver} sources"
  # Depends on JDK to get license files
  depends=("jdk${_majorver}-openjdk=${pkgver}-${pkgrel}")
  provides=("openjdk${_majorver}-src=${pkgver}-${pkgrel}")

  install -Dm 644 -t "${pkgdir}${_jvmdir}/lib" ${_imgdir}/jdk/lib/src.zip

  install -dm 755 "${pkgdir}/usr/share/licenses"
  ln -s ${pkgbase} "${pkgdir}/usr/share/licenses/${pkgname}"
}

package_openjdk24-doc() {
  pkgdesc="OpenJDK Java ${_majorver} documentation"
  # Depends on JDK to get license files
  depends=("jdk${_majorver}-openjdk=${pkgver}-${pkgrel}")
  provides=("openjdk${_majorver}-doc=${pkgver}-${pkgrel}")

  install -dm 755 "${pkgdir}/usr/share/doc"
  cp -r ${_imgdir}/docs "${pkgdir}/usr/share/doc/${pkgbase}"

  install -dm 755 "${pkgdir}/usr/share/licenses"
  ln -s ${pkgbase} "${pkgdir}/usr/share/licenses/${pkgname}"
}

# vim: ts=2 sw=2 et:
