# Maintainer: Daniel Bermond <dbermond@archlinux.org>

pkgname=gromit-mpx
pkgver=1.9.0
pkgrel=1
pkgdesc='On-screen annotation tool'
arch=('x86_64')
url='https://github.com/bk138/gromit-mpx/'
license=('GPL-2.0-or-later')
depends=(
  'cairo'
  'glib2'
  'glibc'
  'gtk3'
  'hicolor-icon-theme'
  'libayatana-appindicator'
  'libx11'
  'libxi'
  'lz4')
makedepends=(
  'cmake'
  'git')
backup=('etc/gromit-mpx/gromit-mpx.cfg')
source=("git+https://github.com/bk138/gromit-mpx.git#tag=${pkgver}")
sha256sums=('8e46c5ce9c1395e4bec303cdcf3a455cd4e32a9a0f8689c79202871b30561733')

prepare() {
  git -C gromit-mpx submodule init
  git -C gromit-mpx config --local submodule.flatpak/shared-modules.update none
  git -C gromit-mpx -c protocol.file.allow='always' submodule update
}

build() {
  cmake -B build -S gromit-mpx \
    -G 'Unix Makefiles' \
    -DCMAKE_BUILD_TYPE:STRING='None' \
    -DCMAKE_INSTALL_PREFIX:PATH='/usr' \
    -DCMAKE_INSTALL_SYSCONFDIR:PATH='/etc' \
    -Wno-dev
  cmake --build build
}

package() {
  DESTDIR="$pkgdir" cmake --install build
}
