# Maintainer: aur.chaotic.cx
# Contributor: novadragon <me@novadragon.space>

## options
: ${_build_debug:=true}

_pkgname="godot-export-templates"
pkgname="$_pkgname-linux"
pkgver="4.7.1"
pkgrel=1
pkgdesc='Godot export templates - Linux x86_64'
url="https://github.com/godotengine/godot"
license=('MIT')
arch=('any')

makedepends=(
  'scons'
  'wayland'
)
optdepends=(
  'godot: use the templates'
)

provides=("$_pkgname")

options=('!strip' '!debug')

_godot_version="$pkgver-stable"
_pkgsrc="godot-$_godot_version"
_pkgext="tar.xz"
source=(
  "$_pkgsrc.$_pkgext"::"$url/releases/download/$_godot_version/$_pkgsrc.$_pkgext"
  "$_pkgsrc.$_pkgext.sha256"::"$url/releases/download/$_godot_version/$_pkgsrc.$_pkgext.sha256"
)
sha256sums=('0230d490846467c4fd772cc70b08dc56cb3adfedd55d039de0af74ddfdba00eb'
            'dac2d061a8e782bc5bdd60be18e079a0f0510188aa27d2542bb68a7b108fd015')

prepare() {
  sha256sum -c "$_pkgsrc.$_pkgext.sha256"
}

build() {
  local _scons_opts=(
    arch=x86_64
    disable_path_overrides=no
    platform=linux
    tools=no
  )

  cd "$_pkgsrc"
  scons "${_scons_opts[@]}" target=template_release

  if [[ "${_build_debug::1}" == "t" ]]; then
    scons "${_scons_opts[@]}" target=template_debug
  fi
}

package() {
  local _templates=('release')

  if [[ "${_build_debug::1}" == "t" ]]; then
    _templates+=('debug')
  fi

  for i in "${_templates[@]}"; do
    install -Dm755 "$_pkgsrc/bin/godot.linuxbsd.template_$i.x86_64" "$pkgdir/usr/share/godot/export_templates/${_godot_version//-/.}/linux_$i.x86_64"
  done

  install -Dm644 "$_pkgsrc/LICENSE.txt" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
