# Maintainer: aur.chaotic.cx

: ${CARGO_HOME:=$SRCDEST/cargo-home}
: ${CARGO_TARGET_DIR:=target}
: ${RUSTUP_TOOLCHAIN:=stable}
export CARGO_HOME CARGO_TARGET_DIR RUSTUP_TOOLCHAIN

_pkgname="findex"
pkgname="$_pkgname-git"
pkgver=0.8.3.r4.gdc7aa2f
pkgrel=1
pkgdesc="A customizable, high-performance finder"
url="https://github.com/mdgaziur/findex"
license=('GPL-3.0-only')
arch=('x86_64')

depends=(
  'gtk3'
  'libkeybinder3'
)
makedepends=(
  'cargo'
  'git'
)

provides=("$_pkgname")
conflicts=("$_pkgname")

options=('!lto')

_pkgsrc="$_pkgname"
source=("$_pkgsrc"::"git+$url.git#branch=development")
sha256sums=('SKIP')

prepare() {
  cd "$_pkgsrc"
  cargo fetch --locked --target host-tuple

  #fix default css path
  local _regex=$(printf 's&/opt/findex/&/usr/share/%s/&g' "$_pkgname")
  sed -E -e "$_regex" -i "crates/findex/src/gui/css.rs"
}

pkgver() {
  cd "$_pkgsrc"
  git describe --long --tags --abbrev=7 --exclude='*[a-zA-Z][a-zA-Z]*' \
    | sed -E 's/^[^0-9]*//;s/([^-]*-g)/r\1/;s/-/./g'
}

build() {
  local _units=$(($(nproc) > 16 ? $(nproc) : 16))
  export CARGO_PROFILE_RELEASE_LTO=false
  export CARGO_PROFILE_RELEASE_CODEGEN_UNITS=$_units

  cd "$_pkgsrc"
  cargo build --release
}

package() {
  cd "$_pkgsrc"
  install -Dm755 "$CARGO_TARGET_DIR/release/findex" "$pkgdir/usr/bin/$_pkgname"
  install -Dm755 "$CARGO_TARGET_DIR/release/findex-daemon" "$pkgdir/usr/bin/$_pkgname-daemon"
  install -Dm644 css/style.css -t "$pkgdir/usr/share/$_pkgname/"
  install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$_pkgname/"
}
